485814_it-IT

liliconcom

Differenza tra i cicli FOR e FOR EACH

Qualcuno può spiegare perché questo:

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For( c = 1, c <= N Items( col ), c++,
 Insert Into( y expr, col[c] );
);

Name Expr(y expr);

produce l'output atteso

Y( :Runtime, :RunPulse, :RstPulse )

ma questo:

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For each({coll, index},col,
 Insert Into( y expr, coll );
);

Name Expr(y expr);

produce questo:

Y( ., ., . )

Mi aspetterei che dia lo stesso risultato? Come devo cambiare PER OGNI ciclo per dare lo stesso risultato?

 

 

SceneggiaturaRe: Differenza tra i cicli FOR e FOR EACH

La mia ipotesi è che le colonne vengano valutate nei valori delle righe correnti in For Each (puoi verificarlo aggiungendo Row() = 1; per esempio). Potresti essere in grado di evitarlo usando Name Expr()

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Fitness.jmp");
col = {:Runtime, :RunPulse, :RstPulse};

y expr = Expr(Y());
For(c = 1, c <= N Items(col), c++,
 Insert Into(y expr, col[c]);
);
Show(Name Expr(y expr));

Row() = 1;
y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, coll);
);
Show(Name Expr(y expr));

y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, Name Expr(coll));
);
Show(Name Expr(y expr));

Re: Differenza tra i cicli FOR e FOR EACH

Sì, è questo.

È un comportamento strano, dal momento che 1. abbiamo l'istruzione For Each Row per la valutazione per riga e 2. For Each dovrebbe trattare un elenco (e sto cercando di lavorare con un elenco di riferimenti a colonne) come il ciclo For.

Si tratta di un bug o è un comportamento previsto?