485814_ja-JP

liliconcom

FORループとFOREACHループの違い

誰かがこれを理由を説明できますか？

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For( c = 1, c <= N Items( col ), c++,
 Insert Into( y expr, col[c] );
);

Name Expr(y expr);

期待される出力を生成します

Y( :Runtime, :RunPulse, :RstPulse )

でも、これ：

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For each({coll, index},col,
 Insert Into( y expr, coll );
);

Name Expr(y expr);

これを生成します：

Y( ., ., . )

同じ結果になると思いますか？ 同じ結果を得るには、FOR EACHループをどのように変更する必要がありますか？

 

 

スクリプティングRe：FORとFOREACHループの違い

私の推測では、列はFor Eachの現在の行の値に評価されます（たとえば、Row（）= 1を追加することでこれをテストできます）。 Name Expr（）を使用すると、これを回避できる場合があります。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Fitness.jmp");
col = {:Runtime, :RunPulse, :RstPulse};

y expr = Expr(Y());
For(c = 1, c <= N Items(col), c++,
 Insert Into(y expr, col[c]);
);
Show(Name Expr(y expr));

Row() = 1;
y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, coll);
);
Show(Name Expr(y expr));

y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, Name Expr(coll));
);
Show(Name Expr(y expr));

Re：FORとFOREACHループの違い

はい、これです。

これは奇妙な動作です。1。行ごとの評価用のForEachRowステートメントがあり、2。 For Eachは、リストをForループと同じように扱う必要があります（列への参照のリストを処理しようとしています）。

これはバグですか、それとも意図された動作ですか？