484727_de-DE

liliconcom

Wie kann der Zoom auf ein Diagramm zurückgesetzt werden, nachdem es durch den lokalen Datenfilter geändert wurde?

Liebe Experten,

 

Mir ist bekannt, dass man den von der Lupe (im Graph Builder) angewendeten Zoom zurücksetzen kann, indem man doppelklickt oder die Alt-Taste gedrückt hält (bei aktivierter Lupe). Diese Funktionalität funktioniert jedoch nicht, wenn beim Vergrößern des Diagramms mithilfe eines lokalen Datenfilters Änderungen am Diagramm vorgenommen werden. Das Vergrößern und Verkleinern (Strg-Taste gedrückt) funktioniert immer noch, aber ich möchte, dass der Zoom auf den ursprünglichen Zustand zurückgesetzt wird.

 

Möglicherweise wird dies in kommenden JMP-Versionen behoben. In der Zwischenzeit könnte ich eine Schaltflächenbox in meiner Bewerbung haben. Irgendwelche Ideen, wie man das macht? Ich habe einige Versuche mit der folgenden Syntax durchgeführt, konnte jedoch keine funktionierende Kombination finden

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

New Window("Big Class Graph",
 V List Box(
  bn = Button Box( "Reset zoom", 
   Report(gb)[GraphBuilderBox(1)] << SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   )
  ),
  
  gb = dt << Graph Builder(
   Show Control Panel( 0 ),
   Variables( X( :height ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 1 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   ) 
  ); 
 )
);

 

Ich verwende JMP 16.

 

Danke,

Janne

 

 

GrafikSkripterstellungBetreff: Wie kann der Zoom in der Grafik zurückgesetzt werden, nachdem sie durch den lokalen Datenfilter geändert wurde?

Hallo alle

 

Vielen Dank für den Vorschlag, die Achse zurücksetzen zu verwenden. Zumindest das Folgende funktioniert bei mir

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

New Window("Big Class Graph",
 V List Box(
  bn = Button Box( "Reset zoom", 
   rgp = gb << report;
   axisbox_x = rgp[axis box( 1 )];
   axisbox_y = rgp[axis box( 2 )];
   axisbox_x << Revert Axis;
   axisbox_y << Revert Axis;
  ),
  
  gb = dt << Graph Builder(
   Show Control Panel( 0 ),
   Variables( X( :height ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 1 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   ) 
  ); 
 )
);

Betreff: Wie kann der Zoom in der Grafik zurückgesetzt werden, nachdem sie durch den lokalen Datenfilter geändert wurde?

Nicht ganz dasselbe, aber ich wähle „Skalen sperren“, damit sich die Achsenskalen durch Filterung nicht ändern.

dt = open("$sample_data\Travel Costs.jmp");

gb = dt << Graph Builder(
 Show Control Panel( 0 ),
 Lock Scales( 1 ),   // "Freeze" the axes
 Variables( X( :Days Advance Purchase ), Y( :Net Cost ) ),
 Elements( Points( X, Y, Legend( 24 ) ), Smoother( X, Y, Legend( 25 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :Booking Day of Week ),
   Display( :Booking Day of Week, N Items( 5 ) )
  )
 ),
 SendToReport(
  Dispatch(
   {},
   "Days Advance Purchase",
   ScaleBox,
   {Format( "Fixed Dec", 12, 0 ), Min( -1.48748767778993 ), Max( 130 ),
   Inc( 20 ), Minor Ticks( 1 ), Label Row( Show Major Grid( 1 ) )}
  ),
  Dispatch(
   {},
   "Net Cost",
   ScaleBox,
   {Format( "Currency", "USD", 12, 0 ), Min( 0 ), Max( 6656.45852 ),
   Inc( 1000 ), Minor Ticks( 1 ), Label Row( Show Major Grid( 1 ) )}
  )
 )
);

Betreff: Wie kann der Zoom in der Grafik zurückgesetzt werden, nachdem sie durch den lokalen Datenfilter geändert wurde?

Sie können die Achse umkehren (auch nach dem Filtern). Machen Sie es einmal für die X-Achse und einmal für die Y-Achse. Sie könnten dies auch unter Ihrer Taste programmieren, aber viel schneller ist es nicht.