484727_it-IT

liliconcom

Come reimpostare lo zoom sul grafico una volta modificato dal filtro dati locale?

Cari esperti,

 

Sono consapevole che è possibile ripristinare lo zoom applicato dalla lente d'ingrandimento (sul generatore di grafici) facendo doppio clic o tenendo premuto il tasto Alt (con la lente d'ingrandimento abilitata). Tuttavia, questa funzionalità non funziona se vengono apportate modifiche al grafico utilizzando il filtro dati locale durante lo zoom dello stato. Lo zoom avanti e lo zoom indietro (tasto Ctrl premuto) funzionano ancora, ma vorrei che lo "zoom resettasse" tornasse allo stato originale.

 

Forse questo è stato risolto nelle prossime versioni di JMP. Nel frattempo, potrei avere una pulsantiera sulla mia domanda. qualche idea sul come farlo? Ho fatto alcune prove con la seguente sintassi ma non sono riuscito a trovare una combinazione funzionante

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

New Window("Big Class Graph",
 V List Box(
  bn = Button Box( "Reset zoom", 
   Report(gb)[GraphBuilderBox(1)] << SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   )
  ),
  
  gb = dt << Graph Builder(
   Show Control Panel( 0 ),
   Variables( X( :height ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 1 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   ) 
  ); 
 )
);

 

Sto eseguendo JMP 16.

 

Grazie,

Janne

 

 

GraficaScriptingRi: Come reimpostare lo zoom sul grafico una volta modificato dal filtro dati locale?

Ciao a tutti

 

Grazie per il suggerimento di utilizzare Revert axis. Almeno seguire funziona per me

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

New Window("Big Class Graph",
 V List Box(
  bn = Button Box( "Reset zoom", 
   rgp = gb << report;
   axisbox_x = rgp[axis box( 1 )];
   axisbox_y = rgp[axis box( 2 )];
   axisbox_x << Revert Axis;
   axisbox_y << Revert Axis;
  ),
  
  gb = dt << Graph Builder(
   Show Control Panel( 0 ),
   Variables( X( :height ), Y( :weight ) ),
   Elements( Points( X, Y, Legend( 1 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "height",
     ScaleBox,
     {Min( 50 ), Max( 75 ), Inc( 5 ), Minor Ticks( 1 )}
    ),
    Dispatch(
     {},
     "weight",
     ScaleBox,
     {Min( 60 ), Max( 180 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   ) 
  ); 
 )
);

Ri: Come reimpostare lo zoom sul grafico una volta modificato dal filtro dati locale?

Non è esattamente la stessa cosa, ma seleziono "Blocca scale" in modo che qualsiasi filtro non modifichi le scale degli assi.

dt = open("$sample_data\Travel Costs.jmp");

gb = dt << Graph Builder(
 Show Control Panel( 0 ),
 Lock Scales( 1 ),   // "Freeze" the axes
 Variables( X( :Days Advance Purchase ), Y( :Net Cost ) ),
 Elements( Points( X, Y, Legend( 24 ) ), Smoother( X, Y, Legend( 25 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :Booking Day of Week ),
   Display( :Booking Day of Week, N Items( 5 ) )
  )
 ),
 SendToReport(
  Dispatch(
   {},
   "Days Advance Purchase",
   ScaleBox,
   {Format( "Fixed Dec", 12, 0 ), Min( -1.48748767778993 ), Max( 130 ),
   Inc( 20 ), Minor Ticks( 1 ), Label Row( Show Major Grid( 1 ) )}
  ),
  Dispatch(
   {},
   "Net Cost",
   ScaleBox,
   {Format( "Currency", "USD", 12, 0 ), Min( 0 ), Max( 6656.45852 ),
   Inc( 1000 ), Minor Ticks( 1 ), Label Row( Show Major Grid( 1 ) )}
  )
 )
);

Ri: Come reimpostare lo zoom sul grafico una volta modificato dal filtro dati locale?

È possibile invertire l'asse (anche dopo il filtraggio). Fallo una volta per l'asse X e una volta per l'asse Y. Puoi anche programmarlo sotto il tuo pulsante, ma non è molto più veloce.