482643_ko-KR

liliconcom

특정 열의 행을 제거하는 방법

안녕,

 

위의 표는 내 데이터 세트의 예일 뿐입니다. 100k 행과 500개 이상의 열이 있습니다. 내 질문은 "aaa"행을 제거하는 방법입니다

해석학Re: 특정 열의 행을 제거하는 방법

최종 결과가 어떻게 되기를 원하는지 잘 모르겠습니다.결과 테이블을 원하는 경우:

Names Default To Here( 1 );
dt = Current Data Table();

// Get all of the column names
colNameList = dt << get column names( string );

// Remove the first column name from the list
Remove From( colNameList, 1, 1 );

dt << Begin Data Update;

// Loop across all columns in the list and recode them
For( i = 1, i <= N Items( colNameList ), i++,
 dt << Recode Column(
  As Column( dt, colNameList[i] ),
  {Map Value( _rcOrig, {"aaa", " "}, Unmatched( _rcNow ) )},
  Update Properties( 1 ),
  Target Column( As Column( dt, colNameList[i] ) )
 )
);

dt << End Data Update;

최종 결과가 다음과 같을 경우

Names Default To Here( 1 );
dt = Current Data Table();

// Get all of the column names
colNameList = dt << get column names( string );

// Remove the first column name from the list
Remove From( colNameList, 1, 1 );

// Loop across all columns in the list and find rows 
// that have aaa for that column
For( i = 1, i <= N Items( colNameList ), i++,
 dt << select where(
  As Column( dt, colNameList[i] ) == "aaa",
  current selection( "extend" )
 )
);

// Delete all selected rows
dt << delete rows;

데이터 표의 이미지를 제공하는 향후 논의를 위해 표의 그림이 아닌 표로 삽입하거나 가능하면 표를 첨부하십시오.이렇게 하면 응답자가 테이블을 개별적으로 생성하는 데 필요한 시간을 소비해야 하는 요구 사항이 제거됩니다.