Salut,
Le tableau ci-dessus n'est qu'un exemple de mon ensemble de données. J'ai 100 000 lignes et plus de 500 colonnes. Ma question est de savoir comment supprimer les lignes "aaa"
Je ne suis pas sûr de ce que vous voulez que le résultat final soit.Si vous voulez que la table résultante soit :
Names Default To Here( 1 );
dt = Current Data Table();
// Get all of the column names
colNameList = dt << get column names( string );
// Remove the first column name from the list
Remove From( colNameList, 1, 1 );
dt << Begin Data Update;
// Loop across all columns in the list and recode them
For( i = 1, i <= N Items( colNameList ), i++,
dt << Recode Column(
As Column( dt, colNameList[i] ),
{Map Value( _rcOrig, {"aaa", " "}, Unmatched( _rcNow ) )},
Update Properties( 1 ),
Target Column( As Column( dt, colNameList[i] ) )
)
);
dt << End Data Update;
Si le résultat final est
Names Default To Here( 1 );
dt = Current Data Table();
// Get all of the column names
colNameList = dt << get column names( string );
// Remove the first column name from the list
Remove From( colNameList, 1, 1 );
// Loop across all columns in the list and find rows
// that have aaa for that column
For( i = 1, i <= N Items( colNameList ), i++,
dt << select where(
As Column( dt, colNameList[i] ) == "aaa",
current selection( "extend" )
)
);
// Delete all selected rows
dt << delete rows;
Pour les discussions futures où vous fournissez une image d'un tableau de données, veuillez l'insérer en tant que tableau et non en tant qu'image du tableau, ou si possible joindre le tableau.Cela supprimera l'obligation pour le répondant d'avoir à passer le temps nécessaire pour créer individuellement le(s) tableau(x).
