Hola,
La tabla anterior es solo un ejemplo de mi conjunto de datos. Tengo 100k filas y más de 500 columnas. Mi pregunta es cómo eliminar las filas "aaa"
No estoy seguro de cuál quieres que sea el resultado final.Si desea que la tabla resultante sea:
Names Default To Here( 1 );
dt = Current Data Table();
// Get all of the column names
colNameList = dt << get column names( string );
// Remove the first column name from the list
Remove From( colNameList, 1, 1 );
dt << Begin Data Update;
// Loop across all columns in the list and recode them
For( i = 1, i <= N Items( colNameList ), i++,
dt << Recode Column(
As Column( dt, colNameList[i] ),
{Map Value( _rcOrig, {"aaa", " "}, Unmatched( _rcNow ) )},
Update Properties( 1 ),
Target Column( As Column( dt, colNameList[i] ) )
)
);
dt << End Data Update;
Si el resultado final es
Names Default To Here( 1 );
dt = Current Data Table();
// Get all of the column names
colNameList = dt << get column names( string );
// Remove the first column name from the list
Remove From( colNameList, 1, 1 );
// Loop across all columns in the list and find rows
// that have aaa for that column
For( i = 1, i <= N Items( colNameList ), i++,
dt << select where(
As Column( dt, colNameList[i] ) == "aaa",
current selection( "extend" )
)
);
// Delete all selected rows
dt << delete rows;
Para debates futuros en los que proporcione una imagen de una tabla de datos, insértela como una tabla y no como una imagen de la tabla o, si es posible, adjunte la tabla.Esto eliminará el requisito de que el respondedor tenga que dedicar el tiempo necesario para crear individualmente la(s) tabla(s).
