Access Fit Group items

tom_abramov

Hello,

I don't understand what is fit group (matrix, list ...).

How can I send a command to specific object in fit group?

Thanks. 

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Group = Fit Group(
Bivariate (Y( :weight ),X( :height )),
Oneway (Y( :weight ),X( :age )),
Oneway (Y( :weight ),X( :sex )));

//What is the way to run quantiles on the first oneway?

Group[Oneway(2)] << Quantiles(1);//this doesn't work

ih

Here are two ways:

1. Save references to each object inside the group.
2. Find the object inside the group's display tree.

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

//The easy way: save references to each element
Group = Fit Group(
	bv1 = Bivariate ( Y( :weight ),X( :height ) ),
	ow1 = Oneway (Y( :weight ),X( :age )),
	ow2 = Oneway (Y( :weight ),X( :sex ))
);

//And send messages like you normally would
ow1 << Quantiles(1);

//The harder way is to find the analysis in the tree structure:
((Group << Find( OutlineBox(5) ) ) << Get Scriptable Object) <<  Quantiles(1);

//Here is how I put the second method together:

//Find the OutlineBox to reference, note the 'helpkey' to verify that you at the right spot
Group << Show Tree Structure;

//Get a reference to the child outlinebox
Group << Find( OutlineBox(5) );

//Get the object that is normally returned from that function, similar to ow2
((Group << Find( OutlineBox(5) ) ) << Get Scriptable Object)