480530_fr-FR

liliconcom

obtenir les valeurs d'un résumé de 5 nombres à partir du graphique à moustaches dans le générateur de graphiques

Salut la communauté JMP,

 

J'ai besoin d'aide avec un script JSL. J'aimerais travailler avec des valeurs multiples du "résumé à 5 nombres" des graphiques en boîte à moustaches dans le générateur de graphiques. Savez-vous comment obtenir ces valeurs - fe dans une liste ou une matrice ? travailler avec ceux-ci après la construction du graphique ?

 

 

 

BR et merci d'avance

Automatisation et scriptsRe : obtenir les valeurs d'un résumé à 5 nombres à partir d'un graphique en boîte à moustaches dans le générateur de graphiques

Cet exemple devrait vous donner les idées et l'approche essentielles :

 

Names Default to Here( 1 );

// example of data
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// launch platform and analyze separately by :sex and save reference to analysis layer
dist = dt << Distribution( Y( :weight ), By( :sex ) );

// get reference to report layer
rpt = dist << Report;

// get reference to all Qunatiles outline boxes
quantile table = rpt << XPath( "//OutlineBox[text()='Quantiles']" );
n rpts = N Items( quantile table );

// prepare empty container for all five-point summaries
summary = J( 5, n rpts, . );

// iterate over all Quantile reports
For( r = 1, r <= n rpts, r++,
 summary[0,r] = Matrix( (quantile table[r])[1][NumberColBox(1)] << Get( { 11, 7, 6, 5, 1 } ) );
);

// survace matrix as a new data table
As Table( summary );

dist << Close Window;

Re : obtenir les valeurs d'un résumé à 5 nombres à partir d'un graphique en boîte à moustaches dans le générateur de graphiques

Merci. J'ai testé la fonction Groupe par dans le script, mais cela ne s'est pas déroulé comme prévu... j'ai adapté @markbailey s script avec : dist << Regrouper par (X (:sex));

Des suggestions, quel pourrait être le problème ici ?

 

BR et merci d'avance

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ), Invisible );
dist << Group By (X( :Sex));
rpt = dist << Report;

five pt summary = { min, q1, med, q3, max } = rpt["Quantiles"][NumberColBox(1)] << Get( { 11, 7, 6, 5, 1 });

dist << Close Window;

 

Re : obtenir les valeurs d'un résumé à 5 nombres à partir d'un graphique en boîte à moustaches dans le générateur de graphiques

L'ajout d'un regroupement ou d'une variable 'by' rend la méthode de @Mark_Bailey un peu plus complexe (mais parfaitement faisable). Cependant, comme alternative, vous pouvez vous baser sur ceci :

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
Summarize( exg = By( :sex ), exm = Mean( :height ), exMax = Max(:height) );
Print(exg, exm, exMax);

Re : obtenir les valeurs d'un résumé à 5 nombres à partir d'un graphique en boîte à moustaches dans le générateur de graphiques

Merci beaucoup pour votre réponse, cela m'a effectivement aidé. Il ne me reste qu'une seule question ouverte : lorsque je crée la distribution, toutes les valeurs de toutes les boîtes sont rassemblées. Existe-t-il une option pour créer la distribution pour différentes valeurs X ? J'essaie de l'expliquer dans mon exemple au-dessus de votre message. Il y a 5 cases pour différentes valeurs x (ici EC1, EC2, LS20,...) Est-il possible de créer ces distributions pour chaque valeur X différente ?

 

BR

Re : obtenir les valeurs d'un résumé à 5 nombres à partir d'un graphique en boîte à moustaches dans le générateur de graphiques

Je n'essaierais pas d'extraire ces informations de Graph Builder. J'utiliserais plutôt une autre plateforme. La plateforme Distribution calcule ces quantiles pour vous. Vous pouvez l'ouvrir en tant que plateforme invisible, extraire les valeurs, puis la fermer. Voir cet exemple :

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dist = dt << Distribution( Y( :weight ), Invisible );
rpt = dist << Report;

five pt summary = { min, q1, med, q3, max } = rpt["Quantiles"][NumberColBox(1)] << Get( { 11, 7, 6, 5, 1 });

dist << Close Window;