480402_ko-KR

liliconcom

컬럼 USL 및 LSL 속성을 변경하는 JMP 스크립트

"Ntwk Osnr 사양 테이블 파일 이름" 변수 내에 저장된 텍스트 파일에서 사양 제한 세트를 가져오는 JMP 스크립트 함수가 있습니다. "Ntwk Osnr 데이터 테이블" 데이터 테이블 내에서 "PctDiff_ModBer_q_calcBer 열"의 USL 및 LSL 열 속성을 변경하려고 합니다. 그러나 다음 JMP 스크립트 명령을 실행할 때 스크립팅 오류가 발생하지 않지만 USL 및 LSL 열 속성은 업데이트되지 않습니다. Spec Limit에서 구한 Spec Limit는 1.7입니다. 다음 줄을 단계별로 실행하면 1.7 값이 Speclimit 변수 내에서 업데이트되지만 USL 및 LSL 열 속성은 업데이트되지 않습니다. Speclimit 변수를 상수 1.7로 설정하면 USL 및 LSL 열 속성이 각각 1.7 및 -1.7로 설정됩니다. 따라서 문제는 텍스트 파일에서 값을 얻는 것이지만 문제를 파악할 수 있습니다. 텍스트 파일에서 사양 제한을 가져와 열 속성을 업데이트하도록 하는 솔루션이 무엇인지 알려주실 수 있나요?

 

Include( "$CommonScriptPath/Function - Obtain Spec Limit Value.jsl" );
Speclimit = ObtainSpecLimit(
 Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc"
);

dt = Open( Ntwk Osnr Data Table Filename, invisible );
Data Table( dt ):PctDiff_ModBer_q_calcBer << Set Property(
 "Spec Limits",
 {LSL( (Speclimit * (-1)) ), USL( Speclimit ), Target( 0 ), Show Limits( 1 )}
);

스크립팅Re: 열 USL 및 LSL 속성을 변경하는 JMP 스크립트

값이 숫자인지 확인하고 Eval(EvalExpr()) 및 Expr()을 사용해 보십시오.

Include("$CommonScriptPath/Function - Obtain Spec Limit Value.jsl");
Speclimit = ObtainSpecLimit(Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc");

dt = Open(Ntwk Osnr Data Table Filename, invisible);
Eval(
 Eval Expr(
  Data Table(dt):PctDiff_ModBer_q_calcBer << Set Property(
   "Spec Limits",
   {LSL(Expr(Speclimit * (-1))), USL(Expr(Speclimit)), Target(0), Show Limits(1)}
  )
 )
);

Eval Insert, Eval Expr, Parse 및 Substitute를 사용하여 한 표현식을 다른 표현식에 삽입

Re: 열 USL 및 LSL 속성을 변경하는 JMP 스크립트

JMP 목록 내에서 지정하는 계산은 실행 전에 평가되지 않습니다.따라서 Substitution 함수가 이를 수행하기 전에 명령문을 완전히 구문 분석하고 평가해야 합니다.

Include( "$CommonScriptPath/Function - Obtain Spec Limit Value.jsl" );
Speclimit = ObtainSpecLimit(
 Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc"
);

dt = Open( Ntwk Osnr Data Table Filename, invisible );

Eval(
 Substitute(
   Expr(
    Data Table( dt ):PctDiff_ModBer_q_calcBer <<
    Set Property(
     "Spec Limits",
     {LSL( __LSL__ ), USL( __USL__ ), Target( 0 ), Show Limits( 1 )}
    )
   ),
  Expr( __LSL__ ), Speclimit * (-1),
  Expr( __USL__ ), Speclimit
 )
);