480402_it-IT

liliconcom

Script JMP che modifica le proprietà USL e LSL della colonna

Ho una funzione script JMP che ottiene una serie di limiti di specifica da un file di testo memorizzato all'interno della variabile "Ntwk Osnr Spec Table Filename". Sto cercando di modificare le proprietà delle colonne USL e LSL della colonna "PctDiff_ModBer_q_calcBer all'interno della tabella dati "Ntwk Osnr Data Table". Ma quando eseguo i seguenti comandi di script JMP non ottengo un errore di scripting ma le proprietà delle colonne USL e LSL non vengono aggiornate. Il limite delle specifiche che si ottiene dal limite delle specifiche è 1,7. Quando passo attraverso le seguenti righe, il valore di 1.7 viene aggiornato all'interno della variabile Speclimit ma le proprietà della colonna USL e LSL non vengono aggiornate. Se imposto la variabile Speclimit su una costante 1,7, le proprietà della colonna USL e LSL sono impostate rispettivamente su 1,7 e -1,7. Quindi il problema deve essere ottenere il valore dal file di testo, ma posso capire il problema. Qualcuno può farmi sapere qual è la soluzione per ottenere il limite delle specifiche da un file di testo e farlo aggiornare le proprietà della colonna.

 

Include( "$CommonScriptPath/Function - Obtain Spec Limit Value.jsl" );
Speclimit = ObtainSpecLimit(
 Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc"
);

dt = Open( Ntwk Osnr Data Table Filename, invisible );
Data Table( dt ):PctDiff_ModBer_q_calcBer << Set Property(
 "Spec Limits",
 {LSL( (Speclimit * (-1)) ), USL( Speclimit ), Target( 0 ), Show Limits( 1 )}
);

SceneggiaturaRe: Script JMP che modifica le proprietà USL e LSL della colonna

Assicurati che i valori siano numerici e prova a usare Eval(EvalExpr()) ed Expr()

Include("$CommonScriptPath/Function - Obtain Spec Limit Value.jsl");
Speclimit = ObtainSpecLimit(Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc");

dt = Open(Ntwk Osnr Data Table Filename, invisible);
Eval(
 Eval Expr(
  Data Table(dt):PctDiff_ModBer_q_calcBer << Set Property(
   "Spec Limits",
   {LSL(Expr(Speclimit * (-1))), USL(Expr(Speclimit)), Target(0), Show Limits(1)}
  )
 )
);

Inserisci un'espressione in un'altra usando Eval Insert, Eval Expr, Parse e Substitute

Re: Script JMP che modifica le proprietà USL e LSL della colonna

I calcoli specificati all'interno di un elenco JMP non verranno valutati prima dell'esecuzione.Pertanto, l'istruzione deve essere completamente analizzata e valutata prima che la funzione di sostituzione lo realizzi

Include( "$CommonScriptPath/Function - Obtain Spec Limit Value.jsl" );
Speclimit = ObtainSpecLimit(
 Ntwk Osnr Spec Table Filename, DeviceType, "*", "*", "ber_diffQcalc"
);

dt = Open( Ntwk Osnr Data Table Filename, invisible );

Eval(
 Substitute(
   Expr(
    Data Table( dt ):PctDiff_ModBer_q_calcBer <<
    Set Property(
     "Spec Limits",
     {LSL( __LSL__ ), USL( __USL__ ), Target( 0 ), Show Limits( 1 )}
    )
   ),
  Expr( __LSL__ ), Speclimit * (-1),
  Expr( __USL__ ), Speclimit
 )
);