480167_it-IT

liliconcom

Come eliminare la colonna e la riga e scegliere il nome di riga specifico come nuova colonna?

Ciao, mi chiamo Jamal. Vengo dalla Malesia e non ho davvero alcuna conoscenza dello scripting JSL. Quindi il mio progetto è, ogni tabella che apro da data Wafer, viene fornita con righe e colonne indesiderate. Quindi il mio obiettivo è che i dati funzioneranno solo se la riga del nome Parametro e altro è una nuova colonna. Inoltre devo eliminare una riga specifica che non ho usato. Quindi la mia domanda a qualcuno esperto di scripting. Puoi annotare il programma che se scelgo una tabella di dati elimina automaticamente l'altra riga all'interno dell'indicatore rosso e crea un parametro di riga come una nuova colonna?

 

P/s non tutte le tabelle di dati hanno lo stesso parametro di riga (44)

Tabella datiSceneggiaturafinestreRi: Come eliminare la colonna e la riga e scegliere il nome di riga specifico come nuova colonna?

Siamo spiacenti, ho dimenticato di inserire la tabella dei dati da Wafer

Ri: Come eliminare la colonna e la riga e scegliere il nome di riga specifico come nuova colonna?

Questo potrebbe fare il trucco:

 

Names Default to Here( 1 );
dt = Current Data Table();
loc = Contains( Column( dt, 1 ) << Get Values, "Parameter" );
dt << Select Rows( 1::loc - 1 ) << Delete Rows;
loc = Contains( Column( dt, 1 ) << Get Values, "PID-1" );
dt << Select Rows( 2::loc - 1 ) << Delete Rows;

For( i = 1, i <= N Col( dt ), i++,
 Column( dt, i ) << Set Name( Column( dt, i )[1] )
);

dt << Select Rows( [1] ) << Delete Rows

Ri: Come eliminare la colonna e la riga e scegliere il nome di riga specifico come nuova colonna?

Ecco il modo in cui affronterei la questione.Apri il file csv in JMP e quindi esegui questo script di seguito.Caricherà i dati globali nelle variabili della tabella, cambierà i nomi delle colonne e quindi convertirà le colonne di test in numeriche, ecc.

Names Default To Here( 1 );
dt = Current Data Table();

// Add Global info as table variables
theRow = 1;
While( Column( dt, 1 )[theRow] != "Parameter",
 If( Column( dt, 2 )[theRow] != "",
  dt << new table variable( Column( dt, 1 )[theRow],
   Column( dt, 2 )[theRow]
  )
 );
 theRow++;
);

// Get rid of unwanted rows
dt << select where( As Column( dt, 3 ) == "" & As Column( dt, 4 ) == "" );
dt << delete rows;

// Rename columns
theRow = (dt << get rows where( As Column( dt, 1 ) == "Parameter" ))[1];
For( i = 1, i <= N Cols( dt ), i++,
 If( Column( dt, i )[theRow] != "",
  Column( dt, i ) << set name( Column( dt, i )[theRow] )
 )
);
dt << delete rows(theRow);

// Attempt to set meta data for columns
// List of know columns
metaList = {
 "SBIN", "numeric", "ordinal",
 "HBIN", "numeric", "ordinal",
 "DIE_X", "numeric", "ordinal",
 "DIE_Y", "numeric", "ordinal",
 "SITE", "numeric", "ordinal",
 "TOTAL_TESTS", "numeric", "continuous",
 "X", "numeric", "ordinal",
 "Y", "numeric", "ordinal",
 "SITE_NO", "numeric", "ordinal",
 "PassFail", "numeric", "ordinal",
 "TimeStamp", "numeric", "timestamp",
 "PartSN", "character", "nominal" 
};
// Process metaList into separate lists for easier processing
colList = {};
typeList = {};
modelList = {};
For( i = 1, i <= N Items( metaList ), i++,
 If(
  Mod( i, 3 ) == 1, Insert Into( colList, metaList[i] ),
  Mod( i, 3 ) == 2, Insert Into( typeList, metaList[i] ),
  Insert Into( modelList, metaList[i] )
 )
);
For( i = 1, i <= N Cols( dt ), i++,
 foundName = Contains( colList, Column( dt, i ) << get name );
 If(
  foundName,
   If(
    Contains( {"ordinal", "nominal", "continuous"}, modelList[foundName] ),
     Column( dt, i ) << dataType( typeList[foundName] ) << modelingtype( modelList[foundName] ),
    modelList[foundName] == "timestamp",
     For( k = 1, k <= N Rows( dt ), k++,
      Column( dt, i )[k] = Word( 1, Char( Column( dt, i )[k] ), "_ " ) || "/" || Word( 2, Char( Column( dt, i )[k] ), "_ " ) || "/"
       || Word( 3, Char( Column( dt, i )[k] ), "_ " ) || " " || Word( 2, Char( Column( dt, i )[k] ), " " )
     );
     Column( dt, i ) << datatype( numeric ) << modelingtype( continuous ) << set informat( "y/m/d h:m:s" ) <<
     Format( "y/m/d h:m:s", 18, 0 );,

   ),
  Is Missing( Num( Column( dt, i )[1] ) ) == 0,
   Column( dt, i ) << datatype( numeric ) << modelingtype( continuous );
  
 );
);