479138_de-DE

liliconcom

Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Hallo alle,

Ich versuche, eine neue Spalte zu generieren, die eine mittlere Spalte von :A nach Gruppen ist, die durch :B, :C, angegeben sind.

Gibt es eine Möglichkeit, dies zu tun, wo :B, :C, ist eine Liste? Ich möchte dies, damit ich es mit Col Dialog füllen kann.

Wenn nicht, gibt es eine Möglichkeit, die Liste in Argumente aufzuteilen?

 

Die erste Zeile unten gibt mir die gewünschten Mittel, während die zweite Zeile mir den Gesamtmittelwert von :A gibt.

mean= New Column("Mean", Formula(Col Mean(:A, :B, :C, )));
mean = New Column("Mean", Formula(Col Mean(:A, {:B, :C, })));

 

Vielen Dank im Voraus.

SkripterstellungBetreff: Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Vielen Dank an alle, das hat mich auf den richtigen Weg gebracht.

Ich lerne immer noch etwas über Ausdrücke und Auswertungen, danke für das Beispiel.

Betreff: Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Natürlich gibt es das.@jthi zeigt eine Möglichkeit, damit umzugehen, indem Sie die Elemente der Liste, die Sie aus Ihrem Dialogfeld erhalten, in Ausdrücke umwandeln.Oder, da JSL eine Programmiersprache ist, bietet es Ihnen alle Strukturen, die Sie zur Lösung des Problems benötigen.Da Sie mit JSL etwas neu sind, empfehle ich Ihnen dringend, einen Blick in den Scripting Guide zu werfen.Es ist der beste Weg, um die Strukturen und Funktionen von JSL kennenzulernen.Das Scripting-Handbuch ist in der JMP-Dokumentationsbibliothek im Pulldown-Menü „Hilfe“ verfügbar.

 

Hier ist eine andere Möglichkeit, das Problem zu lösen, die Ihnen das geben sollte, was Sie wollen

Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
dt = Open( "$SAMPLE_DATA/big class.jmp" );

colList = {"height", "Sex", "Age"};

__vals__ = Concat Items( colList, "," );

Eval(
 Parse(
  Eval Insert(
   "dt << New Column( \!"Mean\!",
     formula( Col Mean( ^__vals__^) )
    )
   ;"
  )
 )
);

Betreff: Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Danke Jim, gäbe es eine Möglichkeit, dies zu tun, wenn die Größe der Liste unbestimmt wäre?

Betreff: Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Wenn Sie Spalten in einer Liste mit dem Format :name verwenden, können Sie auch diese Option verwenden (Idee aus Spaltenliste in Formeln verwenden )

Names Default To Here(1);
// Open Data Table: big class.jmp
// → Data Table( "big class" )
dt = Open("$SAMPLE_DATA/big class.jmp");

col_list = {:height, :Sex, :Age};
formula_expr = Name Expr(Substitute(col_list, Expr(List()), Expr(Col Mean())));

Eval(EvalExpr(
 dt << New Column("Mean", Formula(Expr(formula_expr)));
));

Für die Verwendung von Eval, Eval Expr, Expr, Substitute ... siehe Fügen Sie mit Eval Insert, Eval Expr, Parse und Substitute einen Ausdruck in einen anderen ein

Betreff: Gibt es eine Möglichkeit, eine Liste von Spalten als Gruppenvariablen in die Spalte Mittelwert/Standardabweichung/Median einzugeben?

Hier ist eine einfache Möglichkeit, dies zu lösen

Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
dt = Open( "$SAMPLE_DATA/big class.jmp" );

colList = {"height", "Sex", "Age"};

Eval(
 Substitute(
   Expr(
    dt << New Column( "Mean",
     formula( Col Mean( __one__, __two__, __three__ ) )
    )
   ),
  Expr( __one__ ), Parse( ":" || colList[1] ),
  Expr( __two__ ), Parse( ":" || colList[2] ),
  Expr( __three__ ), Parse( ":" || colList[3] )
 )
);