476908_zh-TW

liliconcom

如何將 Open() 函數的導入設置存儲在單獨的表達式中

我需要使用各種設置打開 CSV 文件。

示例之一如下：

dt = Open(
 filePath,
 Import Settings(
  End Of Line( CRLF, CR, LF ),
  End Of Field( Comma, CSV( 0 ) ),
  Strip Quotes( 1 ),
  Use Apostrophe as Quotation Mark( 0 ),
  Use Regional Settings( 0 ),
  Scan Whole File( 1 ),
  Treat empty columns as numeric( 0 ),
  CompressNumericColumns( 0 ),
  CompressCharacterColumns( 0 ),
  CompressAllowListCheck( 0 ),
  Labels( 1 ),
  Column Names Start( 18 ),
  Data Starts( 19 ),
  Lines To Read( "All" ),
  Year Rule( "20xx" )
 )
);

我想將 Import Settings() 構造中的這些設置存儲為單獨的表達式，然後在打開文件時使用它。

像這樣的東西（但它顯然不是這樣工作的）：

settings1 = Expr(
Import Settings(
<MY import="" settings="" here="">
)
);
settings2 = Expr(
Import Settings(
<SOME other="" import="" settings="" here="">
)
);

if(condition, importSettings = settings1, importSettings = settings2)
dt = Open(
filePath, 
Eval(importSettings)
);</SOME></MY>

腳本回覆：如何將 Open() 函數的導入設定儲存在單獨的表達式中

我想我將不得不多次拼寫 Open() 函數。或嘗試使用 Eval Insert()

回覆：如何在單獨的表達式中儲存 Open() 函數的導入設定

您也許可以使用這裡提到的技術來做一些事情，您可以在不將表達式寫為字串的情況下構造它嗎？

Names Default To Here(1);

open_expr = Expr(Open(filePath));

settings1 = Expr(
	Import Settings(
		End Of Line(CRLF, CR, LF),
		End Of Field(Comma, CSV(0)),
		Strip Quotes(1),
		Use Apostrophe as Quotation Mark(0),
		Use Regional Settings(0),
		Scan Whole File(1),
		Treat empty columns as numeric(0),
		CompressNumericColumns(0),
		CompressCharacterColumns(0),
		CompressAllowListCheck(0),
		Labels(1),
		Column Names Start(1),
		Data Starts(2),
		Lines To Read("All"),
		Year Rule("20xx")
	)
);

Insert Into(open_expr, NameExpr(settings1));
Name Expr(open_expr);