476074_ko-KR

liliconcom

열 전환기 만들기 - 스크립트 JMP

안녕하세요,

이벤트용 Laney의 P' 차트에 대한 열 전환기를 만들려면 도움이 필요합니다.

아래는 내 코드입니다.

먼저, 다음 선을 사용하여 계수를 결정해야 합니다.

z_yyy = Eval( {:"Y1"n} );
z_xx = z_yyy[1] << get values;
z_nnn = Eval( {:N} );
z_nn = z_nnn[1] << get values;
z_rrr = Eval( {:Numéro de lot} );

z_Proportion = E Div( z_xx, z_nn );
z_Pbar = V Sum( z_xx ) / V Sum( z_nn );
z_sigma_est = Root( z_Pbar * (1 - z_Pbar) );
z_zvalue = E Mult( ((z_Proportion - z_Pbar) / z_sigma_est), Root( z_nn ) );
z_nr = N Row( z_zvalue );
z_mRList = {0};
z_m = z_zvalue;
z_m[1, 0] = [];
z_m = z_m |/ [0];
z_mr = Abs( z_m - z_zvalue );
z_nr = N Row( z_mr );
z_mr[z_nr, 0] = [];
z_SigmaZ = Mean( z_mr ) / 1.128;
z_KSigmaZ = 3 * z_SigmaZ;

그런 다음 컬럼 스위처를 개발하고 싶은 곳은 다음과 같습니다.

graph = New Window( chart_title,
Control Chart(
Sample Label( :Numéro de lot ),
Sample Size( :N ),
KSigma( z_KSigmaZ ),
Sort by Row Order( 1 ),
Chart Col( :"Y1"n, P( Limits Precision( 1 ), LCL( -3 ) ) ),
SendToReport(
Dispatch(
{},
"P of Y1",
OutlineBox,
{Set Title( "p'-chart, p of Y1" )}
),
Dispatch(
{"P of Y1"},
"2",
ScaleBox,
{Format( "Fixed Dec", 12, 5 ), Min( -0.00025 ), Max( 0.0025 ),
Inc( 0.00025 ), Minor Ticks( 1 )}
),
Dispatch(
{"P of Y1"},
"1",
ScaleBox,
{Min( 0.5 ), Inc( 1 ), Minor Ticks( 0 )}
),
Dispatch(
{"P of Y1"},
"",
AxisBox,
{Add Axis Label( "Taux de défauts pour Y1" )}
),
Dispatch(
{"P of Y1"},
"Proportion pour RNS",
TextEditBox,
{Set Text( "Taux de défauts pour Y1" )}
),
Column Switcher(
 :Name( "Y1" ),
 {:Name( "Y1" ), :Name( "Y2" ),
 :Name( "Y3" ), :Name( "Y4" )}
 )
)
);
);

그러나 이것은 Chart Col 기능으로 개발되었으며 결정할 Y가 없기 때문에 이 열 전환기를 만드는 방법을 모르겠습니다.

이 요청을 도와주실 수 있나요?

정말 감사합니다,

문안 인사,

세바스찬

품질 및 프로세스 엔지니어링Re: 열 전환기 만들기 - 스크립트 JMP

엄청난! 정확히 내가 원했던 것입니다!

정말 감사합니다!

Re: 열 전환기 만들기 - 스크립트 JMP

그래프 참조가 다시 잘못된 위치에 있습니다. 다음은 문제를 해결하는 방법에 대한 한 가지 제안입니다.

graph_expr = Expr(Graph = Control Chart(

이제 당신은 가질 것입니다 graph_expr 호출 시 그래프로 참조할 수 있는 컨트롤 차트를 생성하는 식입니다.

또한 열 전환기를 추가하기 전에 graph_expr을 호출하거나 graph_expr 식 내에서 열 전환기를 이동해야 합니다. 아래는 내가 사용한 샘플 데이터의 예입니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");

z_KSigmaZ = 0.1;

graph_expr = Expr(
 graph = dt << Control Chart Builder(K Sigma(TBD), Variables(Subgroup(:Sample), Y(:Weight)));
 ColumnSwitcherObject = graph << Column Switcher(:Weight, {:Pin, :"Weight 2"n});
);

Substitute Into(graph_expr, Expr(TBD), z_KSigmaZ);

graph_expr;&nbsp;//&nbsp;calling&nbsp;this&nbsp;will&nbsp;create&nbsp;control&nbsp;chart&nbsp;with&nbsp;column&nbsp;switcher

Re: 열 전환기 만들기 - 스크립트 JMP

내 스크립트는 다음과 같습니다.

 

 Graph=Expr(Control Chart(
    Sample Label( :Numéro de lot ),
    Sample Size( :Nombre de seringues ),
    KSigma(TBD),
    Sort by Row Order( 1 ),
   Chart Col( :"Y1"n, P( Test Beyond Limits( 1 ), Limits Precision( 1 ), LCL( -3 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "P of Y1",
   OutlineBox,
   {Set Title( "p'-chart, p of Y1" )}
  ),
  Dispatch(
   {"P of Y1"},
   "2",
   ScaleBox,
   {Format( "Fixed Dec", 12, 5 ), Min( -0.00025 ), Max( 0.0025 ),
   Inc( 0.00025 ), Minor Ticks( 1 )}
  ),
  Dispatch(
   {"P of Y1"},
   "1",
   ScaleBox,
   {Min( 0.5 ), Inc( 1 ), Minor Ticks( 0 )}
  ),
  Dispatch(
   {"P of Y1"},
   "",
   AxisBox,
   {Add Axis Label( "Taux de défauts pour Y1" )}
  ),
  );
  );
  );
 SubstituteInto(graph, Expr(TBD), z_KSigmaZ);
 ColumnSwitcherObject = graph << Column Switcher( :"Y1"n,{:"Y1"n, :"Y2"n});

Re: 열 전환기 만들기 - 스크립트 JMP

스크립트가 어떻게 생겼는지 모른 채 일반적으로 사용하는 솔루션은 다음과 같습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");

ksigma = 0.1;

Eval(EvalExpr(nw = New Window("window",
 obj = dt << Control Chart Builder(K Sigma(Expr(ksigma)), Variables(Subgroup(:Sample), Y(:Weight)));
)));

Wait(1);
ColumnSwitcherObject = obj << Column Switcher(:Weight, {:Pin, :"Weight 2"n});

Re: 열 전환기 만들기 - 스크립트 JMP

엄청난! 작동하고 있습니다!

그러나 특정 Ksigma를 적용하고 싶기 때문에 코드에 alternateInto를 추가했습니다.

 

 SubstituteInto(graph, Expr(TBD), z_KSigmaZ);
 ColumnSwitcherObject = graph << Column Switcher( :Y1,{:Y1, :Y2} );

그리고 두 개의 창이 생성됩니다 ...

ColumSwitchersObject로 하나의 창만 만드는 방법이 있는지 아십니까?

 

답장을 보내 주셔서 감사합니다.

 

Re: 열 전환기 만들기 - 스크립트 JMP

새 창이 아닌 관리도에 대한 참조를 얻으십시오. 도움이 될 수 있습니다

 

graph = New Window(chart_title,
 cc = Control Chart(

그리고 시도

ColumnSwitcherObject = cc<< Column Switcher( :Y1,{:Y1, :Y2});

 

Re: 열 전환기 만들기 - 스크립트 JMP

스크립트 끝에서 이것을 시도했습니다.

 wait(1);
 ColumnSwitcherObject = graph << Column Switcher( :Y1,{:Y1, :Y2});

하지만 작동하지 않습니다

Re: 열 전환기 만들기 - 스크립트 JMP

스크립팅 인덱스의 도움을 받으면 다음과 같이 작동할 수 있습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(Sample Size(1), Chart Col(:Weight), Chart Type(Run Chart));
wait(1);
ColumnSwitcherObject = obj << Column Switcher(:Weight, {:Pin, :Sample, :Weight, :"Weight 2"n});