475726_es-ES

liliconcom

Selección múltiple de segmentos de partición.

Quiero seleccionar varios segmentos cuando se muestra el modelo de partición. Los segmentos seleccionados irán al archivo jmp de población mala y el resto irá al archivo jmp de población buena. Pero no sé cómo codificarlo para la selección múltiple de segmentos.

Mi código es el siguiente donde puedo hacer la separación en dos categorías:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

obj = Partition(
	Y( :NPN1 ),
	X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
	Method( "Decision Tree" ),
	Validation Portion( .2 )
);
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );
Wait( .5 );
obj << on close(
If( N Items( dt << get selected rows() ) > 0,
dtTemp = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
dt << invert row selection;
dtSEG = dt << subset(  invisible, selected rows( 1 ), selected columns( 0 ) );
filepath = "$Desktop";
Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) );
Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
)
);

Quiero agregar múltiples segmentos, supongamos los resaltados y guárdelos en un archivo jmp

(mala población) y resto de datos en otro archivo jmp (buena población). ¿Alguien puede ayudarme con esta codificación?

Modelado estadístico avanzadoModelado predictivo y aprendizaje automáticoIngeniería de Calidad y ProcesosventanasRe: Selección múltiple de segmentos de partición

Parece que desea permitir la selección de las filas asociadas con varios nodos de hoja a través de la opción LRT 'Seleccionar filas'. Si ese es el caso, es posible que pueda usar un controlador de estado de fila, y el código a continuación debería ayudarlo a comenzar. Tenga en cuenta que esto supone que el usuario no realiza selecciones de filas que no sean a través del informe de partición.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

// Matrix of all rows that were selected
::wasSelected = [];

// Row state handler function
updateWasSelected = Function({x}, {Default Local},
      // 'x' is a column vector of row states that have CHANGED. We just need those that are now selected . . .
      For( i = 1, i <= NRow(x), i++,
       // Need to accumulate selected rows, not adding duplicates
       If( Selected(RowState(x[i])) & !Contains(::wasSelected, x[i]),
        ::wasSelected = VConcat(::wasSelected, x[i]) 
        );
       );
      );
// Assign the handler to the table
rsh = dt << MakeRowStateHandler(updateWasSelected);

// Do the partition and allow user to make selections vis leaf node LRT
obj = dt << Partition(
     Y( :NPN1 ),
     X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
     Method( "Decision Tree" )
    );
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );

// Figure out what has been selected and make the auxilliary tables
obj << onClose(
   If( NRows(::wasSelected) > 0,
    filepath = "$Desktop";
    Try(
     dtTemp = dt << subset( invisible, rows( ::wasSelected ), selected columns( 0 ) );
     Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) ),
     Print("No rows for table!");
     );
    dt << invert row selection;
    Try(
     dtSEG = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
     Close( dtSEG, save( filepath || "\" || "goodpopulation.jmp" ) ),
     Print("No rows for table!");
      );
    );
   dt << clearRowStates;
  );

Re: Selección múltiple de segmentos de particiónMuchas gracias. Probaré este.