475726_it-IT

liliconcom

Selezione multipla di segmenti di partizione

Voglio selezionare più segmenti quando viene mostrato il modello di partizione. I segmenti selezionati andranno nel file jmp di badpopulation e il resto andrà nel file jmp di goodpopulation. Ma non so come codificarlo per la selezione multipla dei segmenti.

Il mio codice è il seguente in cui può effettuare la separazione in due categorie:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

obj = Partition(
 Y( :NPN1 ),
 X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
 Method( "Decision Tree" ),
 Validation Portion( .2 )
);
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );
Wait( .5 );
obj << on close(
If( N Items( dt << get selected rows() ) > 0,
dtTemp = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
dt << invert row selection;
dtSEG = dt << subset(  invisible, selected rows( 1 ), selected columns( 0 ) );
filepath = "$Desktop";
Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) );
Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
)
);

Voglio aggiungere più segmenti, supponiamo quelli evidenziati e inserirli in un file jmp

(badpopulation) e dati di riposo in altri file jmp (goodpopulation) qualcuno può aiutarmi riguardo a questa codifica?

AnaliticaTabella datiSceneggiaturafinestreRe: Selezione multipla di segmenti di partizione

Sembra che tu voglia consentire la selezione delle righe associate a più nodi foglia tramite l'opzione LRT "Seleziona righe". In tal caso, potresti essere in grado di utilizzare un gestore dello stato della riga e il codice seguente dovrebbe iniziare. Si noti che ciò presuppone che l'utente non effettui selezioni di riga se non tramite il report Partizione.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

// Matrix of all rows that were selected
::wasSelected = [];

// Row state handler function
updateWasSelected = Function({x}, {Default Local},
      // 'x' is a column vector of row states that have CHANGED. We just need those that are now selected . . .
      For( i = 1, i <= NRow(x), i++,
       // Need to accumulate selected rows, not adding duplicates
       If( Selected(RowState(x[i])) & !Contains(::wasSelected, x[i]),
        ::wasSelected = VConcat(::wasSelected, x[i]) 
        );
       );
      );
// Assign the handler to the table
rsh = dt << MakeRowStateHandler(updateWasSelected);

// Do the partition and allow user to make selections vis leaf node LRT
obj = dt << Partition(
     Y( :NPN1 ),
     X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
     Method( "Decision Tree" )
    );
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );

// Figure out what has been selected and make the auxilliary tables
obj << onClose(
   If( NRows(::wasSelected) > 0,
    filepath = "$Desktop";
    Try(
     dtTemp = dt << subset( invisible, rows( ::wasSelected ), selected columns( 0 ) );
     Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) ),
     Print("No rows for table!");
     );
    dt << invert row selection;
    Try(
     dtSEG = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
     Close( dtSEG, save( filepath || "\" || "goodpopulation.jmp" ) ),
     Print("No rows for table!");
      );
    );
   dt << clearRowStates;
  );

Re: Selezione multipla di segmenti di partizioneGrazie mille. Proverò questo.