475726_zh-TW

liliconcom

分區段的多重選擇

我想在顯示分區模型時選擇多個段。選定的段落將進入 badpopulation jmp 文件，其餘部分將進入 good population jmp 文件。但我不知道如何對其進行編碼以實現多個段落的選擇。

我的程式碼如下，它可以將其分為兩類：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

obj = Partition(
	Y( :NPN1 ),
	X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
	Method( "Decision Tree" ),
	Validation Portion( .2 )
);
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );
Wait( .5 );
obj << on close(
If( N Items( dt << get selected rows() ) > 0,
dtTemp = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
dt << invert row selection;
dtSEG = dt << subset(  invisible, selected rows( 1 ), selected columns( 0 ) );
filepath = "$Desktop";
Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) );
Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
)
);

我想添加多個段，假設突出顯示的段並將它們放入一個 jmp 檔案中

(badpopulation) 並將剩餘資料放入其他 jmp 檔案(goodpopulation) 任何人都可以幫助我了解此編碼嗎？

進階統計建模預測建模和機器學習品質和工藝工程視窗回复：分區段的多重選擇

也許更好或更簡單的解決方案：

在你建造你的樹之後。 使用 RTM 保存葉子編號

.

然後使用 Fit YbyX 進行方差分析，使用葉數作為 X 並將您的響應作為 Y，然後從樹上摘下“壞”葉子。

 

回复：分區段的多重選擇

在不使用腳本的情況下，有一個很好的解決方案，即使用 JMP 中的點擊功能

 

首先使用葉中的紅色三角菜單 (RTM) 選擇葉中具有“壞”值的行。

Next 從“行”菜單選項卡中命名列中的選擇

 

輸入新列的標題和“壞”行的標籤。

不要為未選擇的行輸入值。 把它留空

 

對每個“壞”葉重複此步驟

 

回复：分區段的多重選擇太感謝了。 我會試試這個。回复：分區段的多重選擇

看起來您想通過“選擇行”LRT 選項允許選擇與多個葉節點關聯的行。 如果是這種情況，您可以使用行狀態處理程序，下面的代碼應該可以幫助您入門。 請注意，這假定用戶不通過分區報告以外的方式進行行選擇。

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );

// Matrix of all rows that were selected
::wasSelected = [];

// Row state handler function
updateWasSelected = Function({x}, {Default Local},
      // 'x' is a column vector of row states that have CHANGED. We just need those that are now selected . . .
      For( i = 1, i <= NRow(x), i++,
       // Need to accumulate selected rows, not adding duplicates
       If( Selected(RowState(x[i])) & !Contains(::wasSelected, x[i]),
        ::wasSelected = VConcat(::wasSelected, x[i]) 
        );
       );
      );
// Assign the handler to the table
rsh = dt << MakeRowStateHandler(updateWasSelected);

// Do the partition and allow user to make selections vis leaf node LRT
obj = dt << Partition(
     Y( :NPN1 ),
     X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
     Method( "Decision Tree" )
    );
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );

// Figure out what has been selected and make the auxilliary tables
obj << onClose(
   If( NRows(::wasSelected) > 0,
    filepath = "$Desktop";
    Try(
     dtTemp = dt << subset( invisible, rows( ::wasSelected ), selected columns( 0 ) );
     Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) ),
     Print("No rows for table!");
     );
    dt << invert row selection;
    Try(
     dtSEG = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
     Close( dtSEG, save( filepath || "\" || "goodpopulation.jmp" ) ),
     Print("No rows for table!");
      );
    );
   dt << clearRowStates;
  );