473051_it-IT

liliconcom

emettere in ciclo for

ciao a tutti, non riesco a capire perché questa formula for loop non funziona. Crea semplicemente una nuova colonna se le unità sono in tempo e poi la converte in Ore. Si allegano anche dati campione. Grazie.

ColNames = dt << get column names( string, Numeric, character, continuous, Nominal );
N Items( ColNames );
For( i = 1, i <= N Items( ColNames ), i++,
If( Ends With( ColNames[i], "(secs)" ),
New Column (Concat(ColNames[i], "_to_", "Hr"), Formula(AS Column(ColNames[i])/3600) ),
Ends With( ColNames[i], "(min)" ),
New Column (Concat(ColNames[i], "_to_", "Hr"), Formula(AS Column(ColNames[i])/60) ),)
);
Wait( 0 );

SceneggiaturaRe: problema in for loop

Il problema è che l'elemento Formula non analizza la formula presentata e quindi inserisce il codice risultante nella formula.Pertanto, ciò che viene presentato all'elemento formula, deve essere esattamente il JSL che deve essere la formula.Di seguito è una rielaborazione del tuo jsl

Names Default To Here( 1 );
dt = Current Data Table();
ColNames = dt << get column names( string, Numeric, character, continuous, Nominal );
//N Items( ColNames );
For( i = 1, i <= N Items( ColNames ), i++,
 If(
  Ends With( ColNames[i], "(secs)" ),
   New Column( Concat( ColNames[i], "_to_", "Hr" ),
    Formula( Eval( Parse( ":\!"" || ColNames[i] || "\!"n / 3600" ) ) )
   ),
  Ends With( ColNames[i], "(min)" ),
   New Column( Concat( ColNames[i], "_to_", "Hr" ),
    Formula( Eval( Parse( ":\!"" || ColNames[i] || "\!"n / 60" ) ) )
   ), 

 )
);

Re: problema in for loop

Potresti anche considerare l'utilizzo Citazione JSL() , che consente al codice di rimanere evidenziato

 

Names Default to Here( 1 );
dt = Current Data Table();

For( i = 1, i <= N Cols( dt ), i++,
 column name = Column( dt, i ) << Get Name;
 If( Ends With( column name, "(secs)" ),
  Eval( Parse( Eval Insert( JSL Quote(
  dt << New Column( "^column name^_to_Hr", Formula( :Name("^column name^" ) / 3600 ) )
  ) ) ) )
 ,
  Ends With( column name, "(min)" ),
  Eval( Parse( Eval Insert( JSL Quote(
  dt << New Column( "^column name^_to_Hr", Formula( :Name("^column name^" ) / 60 ) )
  ) ) ) )

 )
);