みなさん、こんにちは。
ポイントが各箱ひげ図と関連するバイオリン図の中に正確に収まるグラフを作成したかったのです。
グラフビルダーを使用して、ポイントがボックス内に並んでいないことに気付きました。
誰かがこれを修正する方法を知っていますか？
写真を添付します。
X列とオーバーレイ列の両方をX軸にドラッグしてから、オーバーレイ列を取得して[色]ドロップ領域に移動します。
どうもありがとうございました、
手順を試しましたが、うまくいきません。
同時にいくつかの連続変数をx軸に配置したいのですが、それぞれを2つのグループに分けています。 y軸には変数がありません。
目的は、すべての変数を一緒に表示し、それぞれを2つのグループと比較することです。
あなたがアドバイスしたようにした場合、y軸に一度に配置できる変数は1つだけです。これは、すべての変数をまとめると、箱ひげ図で点が整列しないという問題が再び発生するためです。同時に複数の変数が必要です。
ジュゼッペ
記述したとおりにデータテーブルを取得し、それをGraph Builderに渡して、データをスタックするディスプレイを作成してから、GraphBuilderを実行するために行う必要があるすべてのこと。説明のために、次の表に4つの連続変数がある場合（必要な数の連続変数を持つことができます）、
1つはただ使用します
テーブル=>スタック
連続するすべての列をスタックし、グループ列も一緒に運ばれるようにします
また、スタックデータ列の名前をMeasurementに、ソースラベル列の名前をVariableに変更しました。
これで、結果のデータをGraph Builderで使用して、目的のグラフを作成できます。
以下は、最初にJMPが提供するサンプルデータテーブルの1つからサンプルデータテーブルを作成し、次にデータをスタックし、最後にGraphBuilderを使用して上記のグラフを作成するスクリプトです。
Names default to here(1);
// Create a sample data table that has multiple continuous variables with 2 groups
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dt:Site << set name("Group");
dt << select where( :Group<=2 & :lot_id == "lot01" );
dt << invert row selection;
dt << delete rows;
dtSub = dt << Subset(
All rows,
columns( :Group, :NPN1, :NPN2, :NPN3, :NPN4 )
);
close(dt, nosave);
Wait(5); // Wait 5 seconds so one can see the initial data table
// Now just modify the data shape to set it up for Graph Builder to display the
// data as required
// First Stack all of the continuous variables into one column, and create a second
// column that indicates what column each row's value came from
dtStack = dtSub <<
Stack(
columns( :NPN1, :NPN2, :NPN3, :NPN4 ),
Source Label Column( "Variable" ),
Stacked Data Column( "Measurement" )
);
// Now graph the data placing the Variable and Group columns on the X axis and the
// Measurement column on the Y axis
// Also, remove the label from the Y axis
Graph Builder(
Size( 528, 458 ),
Show Control Panel( 0 ),
Variables(
X( :Variable ),
X( :Group, Position( 1 ) ),
Y( :Measurement ),
Color( :Group )
),
Elements(
Contour( X( 1 ), X( 2 ), Y, Legend( 14 ) ),
Box Plot( X( 1 ), X( 2 ), Y, Legend( 13 ) ),
Points( X( 1 ), X( 2 ), Y, Legend( 15 ) )
),
SendToReport(
Dispatch( {}, "Y title", TextEditBox, {Set Text( "" )} ),
Dispatch(
{},
"Graph Builder",
FrameBox,
{DispatchSeg( Poly Seg( "Violin (NPN1>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN1>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN2>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN2>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN3>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN3>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN4>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN4>>2)" ), {Transparency( 0.5 )} )}
),
Dispatch(
{},
"400",
LegendBox,
{Legend Position( {14, [3, 4], 13, [0, 1, 2, -3], 15, [5, 6]} )}
)
)
);
どうもありがとうございます、
あなたの貴重なアドバイスのおかげで、私はついに目標を達成しました。
振り返ってみると、解決策は単純でしたが、先験的に私はあなたが書いたものについて考えていませんでした。 好奇心を持ってお願いします。上付き文字と下付き文字をx軸または縦座標の変数のラベルに付ける方法を知っていますか？
JMPには、この単純でありながら一般的な可能性が欠けていることに気づきました。
JMPの重要性を考えると、この欠点はかなり異常です。
幸運をお祈りしています
ジュゼッペ
JMPは、特殊なサポートを行うUnicode文字セットを使用します
éや½などの文字。 特別なUnicodeなしでファイルを保存します
プレーンテキストとしての文字を自動的に。 このオプションはによって選択されます
ディフォルト。
つまり、このような特殊なUnicode文字をデータテーブルに配置すると、それらが表示されます。
あなたの提案をありがとう。
たとえば、グループの2乗または2を下付き文字として表示する方法を知りたいです。
または、前の例では、表示の高さの2乗を表示します。
したがって、一般的に、上付き文字または下付き文字を使用して軸ラベルを表示する方法。
たとえば、縦軸にBMI（Kg / m ^ 2）と書いた場合、^記号を避けて「^ 2」が二乗されていることをJMPに伝えるにはどうすればよいですか？
幸運をお祈りしています
JMPは、UTF-8とUTF-16の両方のUnicode標準をサポートしています。 詳細については、スクリプトガイドを参照してください。これにより、特別な処理なしでこれらの特殊文字を埋め込むことができます。
JMPは、エスケープ文字列「\！」を使用してこのような文字を印刷することもできます。その後にUnicode文字列が続きます。したがって、ラベルとして指定したものを含めるために、スクリプトウィンドウを開き、次の印刷コマンドをウィンドウに配置します。
print("BMI (Kg / m\!U00B2)");
この行を実行すると、次の行がログに記録され、ラベルに切り取って貼り付けることができます。
"BMI (Kg / m²)"
もっと直接的な道があったらいいのにと思いますが、私はその道を知りません。完全なUnicode文字セットの詳細は、スクリプトガイドに記載されています。
