Buon pomeriggio a tutti,
Volevo creare un grafico in cui i punti cadessero esattamente all'interno di ogni box-plot e la relativa trama del violino.
Usando il generatore di grafici, mi sono reso conto che i punti non si allineano all'interno del riquadro.
Qualcuno ha idea di come risolvere questo problema?
Allego foto.
Trascina sia la colonna X che la colonna Overlay sull'asse X, quindi prendi la colonna Overlay e spostala nell'area di rilascio Colore.
Grazie mille,
Ho provato la procedura, ma non funziona.
Voglio mettere più variabili continue sull'asse x allo stesso tempo e ognuna di esse è divisa in 2 gruppi. Sull'asse y non ho variabili.
L'obiettivo è mostrare tutte le variabili insieme e confrontare ciascuna di esse con due gruppi.
Se facessi come mi hai consigliato posso mettere solo una variabile alla volta sull'asse y perché se metto insieme tutte le variabili si ripresenterebbe il problema che i punti non si allineano nei box-plot; mentre voglio più variabili contemporaneamente.
Giuseppe
Tutto ciò che deve essere fatto per prendere la tabella di dati come la descrivi e passarla a Graph Builder per creare la visualizzazione in cui desideri che impila i dati e quindi eseguire Graph Builder.Per illustrare, data la tabella seguente con 4 variabili continue (potrebbe avere tutte le variabili continue necessarie),
Uno usa solo
Tabelle=>Pila
e impila tutte le colonne continue e si assicura anche che la colonna Gruppo venga portata avanti
Ho anche rinominato la Colonna dei dati in pila in Misurazione e la Colonna dell'etichetta di origine in Variabile
Ora i dati risultanti possono essere utilizzati da Graph Builder per creare il grafico desiderato
Di seguito è riportato uno script che prima crea la tabella di dati di esempio da una delle tabelle di dati di esempio fornite da JMP, quindi impila i dati e infine utilizza Graph Builder per creare il grafico sopra
Names default to here(1);
// Create a sample data table that has multiple continuous variables with 2 groups
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dt:Site << set name("Group");
dt << select where( :Group<=2 & :lot_id == "lot01" );
dt << invert row selection;
dt << delete rows;
dtSub = dt << Subset(
All rows,
columns( :Group, :NPN1, :NPN2, :NPN3, :NPN4 )
);
close(dt, nosave);
Wait(5); // Wait 5 seconds so one can see the initial data table
// Now just modify the data shape to set it up for Graph Builder to display the
// data as required
// First Stack all of the continuous variables into one column, and create a second
// column that indicates what column each row's value came from
dtStack = dtSub <<
Stack(
columns( :NPN1, :NPN2, :NPN3, :NPN4 ),
Source Label Column( "Variable" ),
Stacked Data Column( "Measurement" )
);
// Now graph the data placing the Variable and Group columns on the X axis and the
// Measurement column on the Y axis
// Also, remove the label from the Y axis
Graph Builder(
Size( 528, 458 ),
Show Control Panel( 0 ),
Variables(
X( :Variable ),
X( :Group, Position( 1 ) ),
Y( :Measurement ),
Color( :Group )
),
Elements(
Contour( X( 1 ), X( 2 ), Y, Legend( 14 ) ),
Box Plot( X( 1 ), X( 2 ), Y, Legend( 13 ) ),
Points( X( 1 ), X( 2 ), Y, Legend( 15 ) )
),
SendToReport(
Dispatch( {}, "Y title", TextEditBox, {Set Text( "" )} ),
Dispatch(
{},
"Graph Builder",
FrameBox,
{DispatchSeg( Poly Seg( "Violin (NPN1>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN1>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN2>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN2>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN3>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN3>>2)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN4>>1)" ), {Transparency( 0.5 )} ),
DispatchSeg( Poly Seg( "Violin (NPN4>>2)" ), {Transparency( 0.5 )} )}
),
Dispatch(
{},
"400",
LegendBox,
{Legend Position( {14, [3, 4], 13, [0, 1, 2, -3], 15, [5, 6]} )}
)
)
);
GRAZIE MILLE,
grazie ai tuoi preziosi consigli ho finalmente raggiunto l'obiettivo.
Col senno di poi, la soluzione era semplice, ma a priori non avevo pensato a quello che hai scritto. Ti chiedo una curiosità: sai come mettere apici e pedici alle etichette delle variabili sull'asse x o sulle ordinate?
Ho notato che a JMP manca questa possibilità semplice ma comune.
Questa lacuna è piuttosto anomala data l'importanza di JMP.
Auguri
Giuseppe
JMP utilizza il set di caratteri Unicode, che supporta special
caratteri come é e ½. Salva i file senza Unicode speciale
caratteri come testo normale automaticamente. Questa opzione è selezionata da
predefinito.
In altre parole, se si inseriscono tali caratteri Unicode speciali nella tabella di dati, vengono visualizzati
Grazie per i vostri suggerimenti.
Mi piacerebbe sapere come visualizzare, ad esempio, il gruppo al quadrato o 2 come pedici.
O nell'esempio precedente, l'altezza viene visualizzata al quadrato.
Quindi, in generale, come visualizzare le etichette degli assi con apici o pedici.
Ad esempio, se ho scritto BMI (Kg / m ^ 2) sull'asse delle ordinate come faccio a dire a JMP che "^ 2" è al quadrato evitando il simbolo ^?
Auguri
JMP supporta gli standard Unicode UTF-8 e UTF-16. Vedere la Guida agli script per maggiori dettagli.Consente di incorporare questi caratteri speciali senza una gestione speciale.
JMP può anche stampare tali caratteri utilizzando la stringa di escape "\!" seguito dalla stringa Unicode.Quindi, per includere ciò che hai specificato come etichetta, aprirei una finestra di script e inserirei il seguente comando di stampa nella finestra
print("BMI (Kg / m\!U00B2)");
Dopo aver eseguito questa riga, quanto segue sarà nel registro, che puoi quindi tagliare e incollare nell'etichetta
"BMI (Kg / m²)"
Vorrei che ci fosse un percorso più diretto, ma non ne sono a conoscenza.I dettagli sull'intero set di caratteri Unicode sono disponibili nella Guida agli script
