471544_ko-KR

liliconcom

col 목록 상자를 사용하여 목록에 추가 값 추가

기존 목록에 col 목록 상자의 추가 데이터가 있을 수 있습니까?

예: 과일 = {"사과", "망고", "딸기"}

그런 다음 사용자가 col 목록 상자에서 바나나, 오렌지를 선택하면 과일 목록에 추가됩니다.

 

나는 Fruits = get items를 사용해 보았지만 초기 목록 값만 초기화되었습니다. 도와주세요

다른스크립팅Re: col 목록 상자를 사용하여 목록에 추가 값 추가

다음은 2개의 예입니다.첫 번째는 Col 목록 상자를 사용하는 것입니다.추가 과일 선택 항목이 열 이름이어야 하므로 과일 목록에 추가할 선택 항목으로 Col 목록 상자에 표시됩니다.

Names Default To Here( 1 );
dt=new table("New Fruits",
 new column("Bananas"),
 new column("Oranges")
);
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
 lb = col List Box(dt,all,
  width( 200 ),
  max selected( 1 ),
  nlines( 6 ),
  selList = lb << get selected;
  locList = lb << get selected indices;
  If( Contains( Fruits, selList[1] ) == 0,
   Insert Into( Fruits, selList[1] )
  );
  lb << set selected(locList[1],0);
  show(Fruits);
 )
);

선택하려는 항목이 실제로 열 이름이 아닌 한 이것은 코드를 작성하는 비효율적인 방법인 것 같습니다.선택해야 하는 열 이름이 아닌 경우 List Box()만 사용하면 잘 작동합니다.

Names Default To Here( 1 );
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
 lb = List Box(
  {"Banana", "Orange"},
  width( 200 ),
  max selected( 1 ),
  nlines( 6 ),
  selList = lb << get selected;
  locList = lb << get selected indices;
  If( Contains( Fruits, selList[1] ) == 0,
   Insert Into( Fruits, selList[1] )
  );
  lb << set selected(locList[1],0);
  show(Fruits);
 )
);