471544_de-DE

liliconcom

Fügen Sie zusätzliche Werte zur Liste hinzu, indem Sie das Listenfeld col verwenden

Ist es möglich, dass eine vorhandene Liste zusätzliche Daten aus dem Listenfeld col enthält?

Zum Beispiel: Früchte = {"Apfel", "Mango", "Erdbeere"}

Wenn der Benutzer dann Banane, Orange aus dem Col-Listenfeld auswählt, wird sie der Obstliste hinzugefügt.

 

Ich habe versucht, Fruits = get items zu verwenden, aber nur die anfänglichen Listenwerte werden initialisiert. Bitte helfen

AndereSkripterstellungBetreff: Fügen Sie der Liste zusätzliche Werte hinzu, indem Sie das Listenfeld col verwenden

Hier sind 2 Beispiele.Die erste verwendet eine Col List Box.Es erfordert, dass die zusätzlichen Obstauswahlen Spaltennamen sind, damit sie in der Col List Box als Auswahlmöglichkeiten angezeigt werden, die der Obstliste hinzugefügt werden sollen.

Names Default To Here( 1 );
dt=new table("New Fruits",
 new column("Bananas"),
 new column("Oranges")
);
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
 lb = col List Box(dt,all,
  width( 200 ),
  max selected( 1 ),
  nlines( 6 ),
  selList = lb << get selected;
  locList = lb << get selected indices;
  If( Contains( Fruits, selList[1] ) == 0,
   Insert Into( Fruits, selList[1] )
  );
  lb << set selected(locList[1],0);
  show(Fruits);
 )
);

Dies scheint eine ineffiziente Methode zu sein, dies zu codieren, es sei denn, die Auswahl, die Sie treffen möchten, sind tatsächlich Spaltennamen.Wenn es sich nicht um Spaltennamen handelt, die ausgewählt werden müssen, funktioniert die Verwendung von nur List Box() einwandfrei

Names Default To Here( 1 );
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
 lb = List Box(
  {"Banana", "Orange"},
  width( 200 ),
  max selected( 1 ),
  nlines( 6 ),
  selList = lb << get selected;
  locList = lb << get selected indices;
  If( Contains( Fruits, selList[1] ) == 0,
   Insert Into( Fruits, selList[1] )
  );
  lb << set selected(locList[1],0);
  show(Fruits);
 )
);