471352_es-ES

liliconcom

Establecer usuario en poner como nueva variable

Hola,

 

Estoy buscando crear un script que tome la entrada de un usuario y envíe estas entradas a una tabla de datos.

Mi secuencia de comandos a continuación genera una tabla de datos pero no inserta las variables de usuario, ¿alguien podría ayudarme, ya que creo que no estoy entendiendo cómo insertarlo?

 

v1 = text = " ID"; // two numbers with default

w = New Window( "Synch Request", // opens a window with a title and this content...
    Border Box( top( 20 ), bottom( 20 ), Left( 20 ), Right( 20 ), // window dressing 
        V List Box( // V and H lists nest to organize the display boxes
            H Center Box( Text Box( "Please select the tool you wish to view and the date to view from" ) ), // a second title, centered
            Spacer Box( size( 1, 30 ) ), // a little vertical space
            H List Box( Text Box( "Tool: " ), tool = Text Edit Box( v1 ) ), // data entry
            Spacer Box( size( 1, 10 ) ), // a little vertical space
            H List Box( Text Box( "Date: " ), date = Calendar Box(  ) ), // more data entry
            Spacer Box( size( 1, 30 ) ), // a little vertical space
            H Center Box( // center the button
                Button Box( "Execute", // this script runs when the button is pressed...

                    // make a new table with the values...
                    tool_val = tool << GetSelected();
     date_val = date << GetSelected();
     dt = New Table( "Untitled", 
     New Column( "a", Character, Set Values( tool_val ) ),
     New Column( "b", Numeric,
      "Continuous",
      //Required due to original format
      Format("y/m/d h:m:s"), Set Values( {date} ) ) );
                    
                    
                    // optionally, close the dialog. Or, you might want to run it again...
                    w << closeWindow; // just the dialog, not the report
                )
            )
        )
    )
);

AnalíticaTabla de datossecuencias de comandosRe: Establecer usuario en put como nueva variable

Echa un vistazo al registro, da un mensaje de error bastante bueno.

 

Aquí posiblemente haya un script arreglado con algunas impresiones de apoyo (obtengo valores con algo más que << ser seleccionado, también establezco valores de manera diferente a la nueva tabla).

 

Names Default To Here(1);

v1 = text = " ID"; // two numbers with default

w = New Window("Synch Request", // opens a window with a title and this content...
 Border Box(top(20), bottom(20), Left(20), Right(20), // window dressing 
  V List Box( // V and H lists nest to organize the display boxes
   H Center Box(Text Box("Please select the tool you wish to view and the date to view from")), // a second title, centered
   Spacer Box(size(1, 30)), // a little vertical space
   H List Box(Text Box("Tool: "), tool = Text Edit Box(v1)), // data entry
   Spacer Box(size(1, 10)), // a little vertical space
   H List Box(Text Box("Date: "), date = Calendar Box()), // more data entry
   Spacer Box(size(1, 30)), // a little vertical space
   H Center Box( // center the button
    Button Box("Execute", // this script runs when the button is pressed...

     // make a new table with the values...
     tool_val = tool << get text;
     show(tool_val);
     date_val = date << get date;
     show(date_val);
     dt = New Table("Untitled",
      New Column("a", Character, Values(Eval List({tool_val}))),
      New Column("b",
       Numeric,
       "Continuous", 
      //Required due to original format
       Format("y/m/d h:m:s"),
       Values(Eval List({date_val}))
      )
     );
                    // optionally, close the dialog. Or, you might want to run it again...
     w << closeWindow; // just the dialog, not the report
    )
   )
  )
 )
);

Dependiendo de su secuencia de comandos, también podría ser una buena idea considerar usar la ventana modal