Existe-t-il un moyen simple de créer un script pour les macros Fit Model ?Je n'arrive pas à croire que je n'ai jamais demandé cela auparavant, mais est-ce que quelqu'un sait si je peux donner à un script exactement quelle macro exécuter sur ce que j'ai sélectionné?
Par exemple, je veux faire une surface de réponse sur "Âge" et "Poids"
Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");
dt << Clear Column Selection();
dt << Select Columns({"weight", "age"});
fm = dt << Fit Model(Y(:height),
// do something involving Response Surface
);
// So that the final report looks the same as.
fm_real = dt << Fit Model(
Y( :height ),
Effects( :age, :weight & RS, :age * :weight, :weight * :weight ),
Personality( "Standard Least Squares" ),
Emphasis( "Effect Leverage" ),
Run()
);
J'ai construit un tas de fonctions d'assistance pour le faire auparavant et je ne veux vraiment pas avoir à les construire à nouveau.
ScriptRe : Existe-t-il un moyen simple de créer un script pour les macros Fit Model ?Essaye ça:
Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");
dialog = dt << Fit Model(
Personality( "Standard Least Squares" ),
Emphasis( "Effect Leverage" ),
);
dialog << Y( :height );
dialog << Effects(Response Surface(:weight, :age));
dialog << Run();
Re : Existe-t-il un moyen simple de créer un script pour les macros Fit Model ?Étonnante. Existe-t-il une documentation à ce sujet ?Ce n'est pas dans le guide de script ou l'index.Puis-je faire une factorielle au degré X ?
*Modifier* J'ai compris.On dirait que c'est juste le libellé exact de la macro.
Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");
dialog = dt << Fit Model(
Personality( "Standard Least Squares" ),
Emphasis( "Effect Leverage" ),
);
dialog << Y( :height );
dialog << Effects(FactorialtoDegree(2, :weight, :age));
@ben_ph cela pourrait vous être utile aussi.
Re : Existe-t-il un moyen simple de créer un script pour les macros Fit Model ?J'ai ajouté sa documentation OSI à JMP17. Vous devriez pouvoir le trouver sous OSI > Objets > Ajuster le modèle > Boîte de dialogue du modèle > Messages d'élément > Effets.
Pour FactorialToDegree et aussi PolynomialToDegree, ce que vous avez fait n'est pas ce que vous pensez. Les arguments à côté des noms de macro sont interprétés comme des colonnes. Ainsi, dans votre exemple, le nombre 2 est interprété comme la deuxième colonne, qui est :age. Et FactorialToDegree et PolynomialToDegree feront référence à la valeur dans la zone d'édition du nombre de degrés comme valeur du degré.
Dans JMP 16 et les versions précédentes, vous devrez peut-être passer par des scripts de zone d'affichage pour changer cela. Par exemple
Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");
dialog = dt << Fit Model(
Personality( "Standard Least Squares" ),
Emphasis( "Effect Leverage" ),
);
report(dialog)[NumberEditBox(1)] << set (3);
dialog << Effects(FactorialtoDegree(:height, :weight, :age));
J'ai fait une petite amélioration dans JMP17. Vous le verrez dans l'élément Effects OSI lorsque vous aurez JMP17.
