如何仅获取数据表中列的“Cp”值？你好，
我想为我的数据表中的一列获取 Cp 值，以便在多个脚本位置使用它来制表。 使用可用函数“obj << Process Capability(LSL(5), Target(40), USL(75));”很明显，我们可以在一个图中获得所有过程能力参数。 但是，我想获取一列的 Cp 值并将其分配给我的脚本中的一个变量，以便在多个脚本位置使用它。
分析数据表脚本视窗回复：如何仅获取数据表中列的“Cp”值？这个小脚本将返回 Cities 样本数据表中 PM10 列的 Cp。它运行分发平台并剥离计算的 Cp。
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Distribution( invisible, Column( :PM10 ) );
obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );
cp = (Report( obj )["Within Sigma Capability"][Number Col Box( 1 )] << get)[4];
Report( obj ) << close window;
Show( cp );
cp = 1.10998512783867;
回复：如何仅获取数据表中列的“Cp”值？运行平台一次，右键单击正确的表并选择 make into datatable，检查结果表表脚本，最后从结果表中获取值。 通过这些步骤，您可以构建脚本并根据需要对其进行修改。 下面是一个示例，使用脚本索引示例构建并制作成数据表的表脚本（以及我自己的一些修改）：
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
dist = dt << Distribution(Column(:PM10), invisible);
dist << Process Capability(LSL(5), Target(40), USL(75));
dt_result = Report(dist)[Outline Box("Distributions")][Outline Box("PM10")][Outline Box("Process Capability")][Outline Box("PM10 Capability")][
Outline Box("Within Sigma Capability")][Table Box(1)] << Make Into Data Table(invisible);
Report(dist) << Close Window;
cp_idx = Loc(dt_result[0, "Index"], "Cp")[1];
cp_value = Column(dt_result, "Estimate")[cp_idx];
Show(cp_value);
Close(dt_result, no save);回复：如何仅获取数据表中列的“Cp”值？谢谢吉姆！！
回复：如何仅获取数据表中列的“Cp”值？谢谢亚莫！！
回复：如何获取数据表中某一列的“Cp”值？我会将值保存到关联数组中，除非需要知道索引。关联数组将被排序，但您可以使用键值访问值：
aa_capability = Associative Array(
(Report(obj)["Within Sigma Capability"][String Col Box(1)] << get),
(Report(obj)["Within Sigma Capability"][Number Col Box(1)] << get)
);
show(aa_capability);
show(aa_capability["Cp"]);
回复：如何获取数据表中某一列的“Cp”值？谢谢 Jarmo ！！通过他们的名字可以轻松访问该流程！！
由于我不完全了解关联数组，所以我无法控制自己。
提到的代码片段返回了关联数组的以下输出：
show(aa_capability);
show(aa_capability["Cp"]);
aa_capability = ["Cp" => 2.68240606599007, "Cpk" => 1.19967417960853, "Cpl" => 1.19967417960853, "Cpm" => 0.742413736498107, "Cpu" => 4.16513795237162];
aa_capability["Cp"] = 2.68240606599007;
回复：如何获取数据表中某一列的“Cp”值？对于关联数组，我建议阅读关联数组（jmp.com）以了解有关关联数组的更多信息。
从 jmp.com 中的关联数组第一页中总结出一些重要内容：
关联数组将唯一键映射到可以非唯一的值
与键关联的值可以是数字、日期、矩阵、列表等等。
虽然关联数组通常没有顺序，但在 JMP 中，为了进行迭代和序列化，键会按字母数字顺序返回。
其余页面可以在左侧面板中找到：
您也可以通过页面右上角的 > 移动到下一页：
