468761_es-ES

liliconcom

¿Cómo obtener solo el valor "Cp" para una columna en un Datatable?

Hola,

 

Me gustaría obtener el valor de Cp para una columna en mi tabla de datos para usarlo en varias ubicaciones de secuencias de comandos para tabularlo. Con la función disponible "obj << Capacidad de proceso (LSL (5), Objetivo (40), USL (75));" está claro que podemos obtener todos los parámetros de capacidad del proceso en un gráfico. Sin embargo, me gustaría obtener el valor de Cp para una columna y asignarlo a una variable en mi secuencia de comandos para usarlo en varias ubicaciones de secuencias de comandos.

AnalíticaTabla de datossecuencias de comandosventanasRe: ¿Cómo obtener solo el valor "Cp" para una columna en un Datatable?

Este pequeño script devolverá el Cp para la columna PM10 en la tabla de datos de ejemplo de Ciudades.Ejecuta la plataforma de distribución y elimina el Cp calculado.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Distribution( invisible, Column( :PM10 ) );
obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );
cp = (Report( obj )["Within Sigma Capability"][Number Col Box( 1 )] << get)[4];
Report( obj ) << close window;
Show( cp );

cp = 1.10998512783867;

Re: ¿Cómo obtener solo el valor "Cp" para una columna en un Datatable?

Ejecute la plataforma una vez, haga clic derecho en la tabla correcta y elija convertir en tabla de datos, verifique el script de la tabla de tablas de resultados y finalmente obtenga el valor de la tabla de resultados. A partir de estos pasos, puede crear el script y modificarlo según sea necesario. A continuación se muestra un ejemplo, creado con un ejemplo de índice de secuencias de comandos y convertido en la secuencia de comandos de tabla de datatable (y algunas de mis propias modificaciones):

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
dist = dt << Distribution(Column(:PM10), invisible);
dist << Process Capability(LSL(5), Target(40), USL(75));

dt_result = Report(dist)[Outline Box("Distributions")][Outline Box("PM10")][Outline Box("Process Capability")][Outline Box("PM10 Capability")][
Outline Box("Within Sigma Capability")][Table Box(1)] << Make Into Data Table(invisible);
Report(dist) << Close Window;

cp_idx = Loc(dt_result[0, "Index"], "Cp")[1];
cp_value = Column(dt_result, "Estimate")[cp_idx];
Show(cp_value);
Close(dt_result, no save);

Re: ¿Cómo obtener solo el valor "Cp" para una columna en un Datatable?

gracias jim!!

Re: ¿Cómo obtener solo el valor "Cp" para una columna en un Datatable?

Gracias Jarmo!!