データテーブルの列の「Cp」値のみを取得するにはどうすればよいですか？やあ、
データテーブルの列のCp値を取得して、複数のスクリプトの場所で使用して表にしたいと思います。 使用可能な関数「obj<分析データ表スクリプティングウィンドウズ
Re：データテーブルの列の「Cp」値のみを取得するにはどうすればよいですか？この小さなスクリプトは、Citiesサンプルデータテーブルの列PM10のCpを返します。ディストリビューションプラットフォームを実行し、計算されたCpを取り除きます。
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Distribution( invisible, Column( :PM10 ) );
obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );
cp = (Report( obj )["Within Sigma Capability"][Number Col Box( 1 )] << get)[4];
Report( obj ) << close window;
Show( cp );
cp = 1.10998512783867;
Re：データテーブルの列の「Cp」値のみを取得するにはどうすればよいですか？プラットフォームを1回実行し、正しいテーブルを右クリックして[データテーブルにする]を選択し、結果テーブルテーブルスクリプトをチェックアウトして、最後に結果テーブルから値を取得します。 これらの手順から、スクリプトを作成し、必要に応じて変更できます。 以下は、スクリプトインデックスの例を使用して構築され、datatableのテーブルスクリプト（および私自身のいくつかの変更）に組み込まれた1つの例です。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
dist = dt << Distribution(Column(:PM10), invisible);
dist << Process Capability(LSL(5), Target(40), USL(75));
dt_result = Report(dist)[Outline Box("Distributions")][Outline Box("PM10")][Outline Box("Process Capability")][Outline Box("PM10 Capability")][
Outline Box("Within Sigma Capability")][Table Box(1)] << Make Into Data Table(invisible);
Report(dist) << Close Window;
cp_idx = Loc(dt_result[0, "Index"], "Cp")[1];
cp_value = Column(dt_result, "Estimate")[cp_idx];
Show(cp_value);
Close(dt_result, no save);Re：データテーブルの列の「Cp」値のみを取得するにはどうすればよいですか？ありがとうジム!!
Re：データテーブルの列の「Cp」値のみを取得するにはどうすればよいですか？ありがとうJarmo!!
Re: データテーブル内の列の「Cp」値のみを取得するにはどうすればいいですか?インデックスを知る必要がない限り、値を連想配列に保存します。連想配列はソートされますが、キー値を使用して値にアクセスできます。
aa_capability = Associative Array(
(Report(obj)["Within Sigma Capability"][String Col Box(1)] << get),
(Report(obj)["Within Sigma Capability"][Number Col Box(1)] << get)
);
show(aa_capability);
show(aa_capability["Cp"]);
Re: データテーブル内の列の「Cp」値のみを取得するにはどうすればいいですか?ありがとう、Jarmo !! 名前でプロセスに簡単にアクセスできるようになりました !!
連想配列について十分に理解していなかったため、どうしようもありませんでした。
上記のスニペットは、連想配列の次の出力を返しました。
show(aa_capability);
show(aa_capability["Cp"]);
aa_capability = ["Cp" => 2.68240606599007, "Cpk" => 1.19967417960853, "Cpl" => 1.19967417960853, "Cpm" => 0.742413736498107, "Cpu" => 4.16513795237162];
aa_capability["Cp"] = 2.68240606599007;
Re: データテーブル内の列の「Cp」値のみを取得するにはどうすればいいですか?連想配列の詳細については、 「Associative Arrays (jmp.com)」を読むことをお勧めします。
jmp.com の連想配列の最初のページから、重要な点をいくつか紹介します。
連想配列は、一意のキーを一意でない値にマッピングします。
キーに関連付けられる値には、数値、日付、行列、リストなどがあります。
連想配列は通常順序付けられていませんが、JMP では反復処理とシリアル化のためにキーは英数字順に返されます。
残りのページは左側のパネルから見つかります:
ページの右上隅にある > から次のページに移動することもできます。
