Comment obtenir uniquement la valeur "Cp" pour une colonne dans un Datatable ?Salut,
Je voudrais obtenir la valeur Cp pour une colonne de ma table de données afin de l'utiliser dans plusieurs emplacements de script pour la tabuler. Avec la fonction disponible "obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );" il est clair que nous pouvons obtenir tous les paramètres de capabilité du processus dans un graphique. Cependant, je voudrais obtenir la valeur Cp pour une colonne et l'affecter à une variable dans mon script pour l'utiliser dans plusieurs emplacements de script.
AnalytiqueTableau de donnéesScriptles fenêtresRe : Comment obtenir uniquement la valeur "Cp" pour une colonne dans un Datatable ?Ce petit script renverra le Cp pour la colonne PM10 dans l'exemple de table de données Cities.Il exécute la plate-forme de distribution et supprime le Cp calculé.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Distribution( invisible, Column( :PM10 ) );
obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );
cp = (Report( obj )["Within Sigma Capability"][Number Col Box( 1 )] << get)[4];
Report( obj ) << close window;
Show( cp );
cp = 1.10998512783867;
Re : Comment obtenir uniquement la valeur "Cp" pour une colonne dans un Datatable ?Exécutez la plate-forme une fois, faites un clic droit sur la table correcte et choisissez transformer en table de données, consultez le script de table de résultats et enfin obtenez la valeur de la table de résultats. À partir de ces étapes, vous pouvez créer le script et le modifier si nécessaire. Vous trouverez ci-dessous un exemple, construit à l'aide d'un exemple d'index de script et transformé en script de table de datatable (et quelques-unes de mes propres modifications):
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
dist = dt << Distribution(Column(:PM10), invisible);
dist << Process Capability(LSL(5), Target(40), USL(75));
dt_result = Report(dist)[Outline Box("Distributions")][Outline Box("PM10")][Outline Box("Process Capability")][Outline Box("PM10 Capability")][
Outline Box("Within Sigma Capability")][Table Box(1)] << Make Into Data Table(invisible);
Report(dist) << Close Window;
cp_idx = Loc(dt_result[0, "Index"], "Cp")[1];
cp_value = Column(dt_result, "Estimate")[cp_idx];
Show(cp_value);
Close(dt_result, no save);Re : Comment obtenir uniquement la valeur "Cp" pour une colonne dans un Datatable ?Merci Jim !!
Re : Comment obtenir uniquement la valeur "Cp" pour une colonne dans un Datatable ?Merci Jarmo !!
Re : Comment obtenir uniquement la valeur « Cp » pour une colonne dans une table de données ?Je sauvegarderais les valeurs dans un tableau associatif, sauf s'il est nécessaire de connaître les indices. Le tableau associatif sera trié, mais vous pouvez accéder aux valeurs avec la clé value :
aa_capability = Associative Array(
(Report(obj)["Within Sigma Capability"][String Col Box(1)] << get),
(Report(obj)["Within Sigma Capability"][Number Col Box(1)] << get)
);
show(aa_capability);
show(aa_capability["Cp"]);
Re : Comment obtenir uniquement la valeur « Cp » pour une colonne dans une table de données ?Merci Jarmo !! Cela a rendu le processus facile d'accès par leurs noms !!
Comme je n'étais pas pleinement conscient du tableau associatif, je ne pouvais pas m'en empêcher.
L'extrait mentionné a renvoyé la sortie suivante du tableau associatif :
show(aa_capability);
show(aa_capability["Cp"]);
aa_capability = ["Cp" => 2.68240606599007, "Cpk" => 1.19967417960853, "Cpl" => 1.19967417960853, "Cpm" => 0.742413736498107, "Cpu" => 4.16513795237162];
aa_capability["Cp"] = 2.68240606599007;
Re : Comment obtenir uniquement la valeur « Cp » pour une colonne dans une table de données ?Pour les tableaux associatifs, je suggère de lire Tableaux associatifs (jmp.com) pour en savoir plus sur les tableaux associatifs.
Quelques éléments importants de la première page des tableaux associatifs sur jmp.com :
Un tableau associatif associe des clés uniques à des valeurs qui peuvent être non uniques
La valeur associée à une clé peut être un nombre, une date, une matrice, une liste, etc.
Bien que les tableaux associatifs ne soient généralement pas ordonnés, dans JMP, les clés sont renvoyées dans l'ordre alphanumérique à des fins d'itération et de sérialisation.
Le reste des pages se trouve dans le panneau de gauche :
Vous pouvez également passer à la page suivante à partir du > dans le coin supérieur droit de la page :
