Wie bekomme ich nur den "Cp" -Wert für eine Spalte in einer Datentabelle?Hallo,
Ich möchte den Cp-Wert für eine Spalte in meiner Datentabelle erhalten, um ihn an mehreren Skriptstandorten zu verwenden, um ihn zu tabellieren. Mit der verfügbaren Funktion "obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );" Es ist klar, dass wir alle Prozessfähigkeitsparameter in einem Diagramm erhalten können. Ich möchte jedoch den Cp-Wert für eine Spalte erhalten und ihn einer Variablen in meinem Skript zuweisen, um ihn an mehreren Skriptstandorten zu verwenden.
AnalytikDatentabelleSkripterstellungWindowsBetreff: Wie bekomme ich nur den "Cp"-Wert für eine Spalte in einer Datentabelle?Dieses kleine Skript gibt den Cp für die Spalte PM10 in der Beispieldatentabelle Städte zurück.Es führt die Distributionsplattform aus und streift den berechneten Cp ab.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Distribution( invisible, Column( :PM10 ) );
obj << Process Capability( LSL( 5 ), Target( 40 ), USL( 75 ) );
cp = (Report( obj )["Within Sigma Capability"][Number Col Box( 1 )] << get)[4];
Report( obj ) << close window;
Show( cp );
cp = 1.10998512783867;
Betreff: Wie bekomme ich nur den "Cp"-Wert für eine Spalte in einer Datentabelle?Führen Sie die Plattform einmal aus, klicken Sie mit der rechten Maustaste auf die richtige Tabelle und wählen Sie In Datentabelle erstellen aus, sehen Sie sich das Tabellenskript für Ergebnistabellen an und erhalten Sie schließlich einen Wert aus der Ergebnistabelle. Anhand dieser Schritte können Sie das Skript erstellen und nach Bedarf ändern. Unten ist ein Beispiel, das mit einem Skript-Indexbeispiel erstellt und in das Tabellenskript von datatable umgewandelt wurde (und einige meiner eigenen Modifikationen):
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
dist = dt << Distribution(Column(:PM10), invisible);
dist << Process Capability(LSL(5), Target(40), USL(75));
dt_result = Report(dist)[Outline Box("Distributions")][Outline Box("PM10")][Outline Box("Process Capability")][Outline Box("PM10 Capability")][
Outline Box("Within Sigma Capability")][Table Box(1)] << Make Into Data Table(invisible);
Report(dist) << Close Window;
cp_idx = Loc(dt_result[0, "Index"], "Cp")[1];
cp_value = Column(dt_result, "Estimate")[cp_idx];
Show(cp_value);
Close(dt_result, no save);Betreff: Wie bekomme ich nur den "Cp"-Wert für eine Spalte in einer Datentabelle?Danke Jim!!
Betreff: Wie bekomme ich nur den "Cp"-Wert für eine Spalte in einer Datentabelle?Danke Jarmo!!
Betreff: Wie erhalte ich nur den „Cp“-Wert für eine Spalte in einer Datentabelle?Ich würde die Werte in einem assoziativen Array speichern, sofern es nicht notwendig ist, die Indizes zu kennen. Assoziative Arrays werden sortiert, aber Sie können auf die Werte mit dem Schlüsselwert zugreifen:
aa_capability = Associative Array(
(Report(obj)["Within Sigma Capability"][String Col Box(1)] << get),
(Report(obj)["Within Sigma Capability"][Number Col Box(1)] << get)
);
show(aa_capability);
show(aa_capability["Cp"]);
Betreff: Wie erhalte ich nur den „Cp“-Wert für eine Spalte in einer Datentabelle?Danke, Jarmo!! Der Vorgang war anhand der Namen leicht zugänglich!!
Da ich mit dem assoziativen Array nicht ganz vertraut war, konnte ich nicht anders.
Der erwähnte Codeausschnitt hat die folgende Ausgabe des assoziativen Arrays zurückgegeben:
show(aa_capability);
show(aa_capability["Cp"]);
aa_capability = ["Cp" => 2.68240606599007, "Cpk" => 1.19967417960853, "Cpl" => 1.19967417960853, "Cpm" => 0.742413736498107, "Cpu" => 4.16513795237162];
aa_capability["Cp"] = 2.68240606599007;
Betreff: Wie erhalte ich nur den „Cp“-Wert für eine Spalte in einer Datentabelle?Für assoziative Arrays empfehle ich die Lektüre von Associative Arrays (jmp.com), um mehr über assoziative Arrays zu erfahren.
Einige wichtige Dinge von der ersten Seite der Associative Arrays in jmp.com:
Ein assoziatives Array ordnet eindeutige Schlüssel Werten zu, die nicht eindeutig sein können.
Der einem Schlüssel zugeordnete Wert kann eine Zahl, ein Datum, eine Matrix, eine Liste usw. sein.
Obwohl assoziative Arrays normalerweise nicht geordnet sind, werden in JMP Schlüssel zum Zweck der Iteration und Serialisierung in alphanumerischer Reihenfolge zurückgegeben.
Die restlichen Seiten finden Sie im Bereich links:
Sie können auch über > oben rechts auf der Seite zur nächsten Seite wechseln:
