466277_fr-FR

liliconcom

Joindre des tables complexes

J'essaie de combiner quelques tables et j'ai quelques problèmes. En gros, mes fiches techniques ressemblent à ce qui suit

 

	Âge	Sexe
Patient A	13	M
Patient B	15	F

 

	Diagnostic
Patient A	Diabète
Patient A	HTN
Patient B	Asthme
Patient B	HTN
Patient B	État septique

 

J'essaie de créer un tableau pour combiner les diagnostics avec les codes des patients (pour ressembler au tableau ci-dessous), mais chaque diagnostic de patient est représenté individuellement dans mon format Excel actuel plutôt que de combiner chaque patient avec tous ses diagnostics. Existe-t-il un moyen simple de combiner ces deux tables ? Merci!

	Âge	Sexe	Diabète	HTN	Asthme	État septique
Patient A	13	M	1	1	0	0
Patient B	15	F	0	1	1	1

 

 

 

 

Tableau de donnéesRe : Joindre des tables complexes

C'est assez facile à faire avec une petite manipulation en utilisant Tableaux->Fractionner sur le tableau de diagnostic en premier. Il vous suffit d'ajouter une troisième colonne de 1 que vous diviserez.

Il vous suffit d'ajouter une troisième colonne de 1 que vous diviserez.

Ensuite, il s'agit de rechercher et de remplacer les valeurs manquantes (.) par des 0 et d'utiliser Tables->Rejoindre par Patient.

 

 

 

Re : Joindre des tables complexes

La réponse de Jeff est une excellente réponse.Voici ma version, qui utilise le JSL créé en utilisant des étapes similaires à celles utilisées par Jeff, pour créer la nouvelle table

names default to here(1);

dtData = New Table( "The Data",
 Add Rows( 5 ),
 New Column( "Patient ID",
  Character,
  "Nominal",
  Set Values(
   {"Patient A", "Patient A", "Patient B", "Patient B", "Patient B"}
  )
 ),
 New Column( "Diagnosis",
  Character( 16 ),
  "Nominal",
  Set Values( {"Diabetes", "HTN", "Asthma", "HTN", "Sepsis"} )
 )
);
dtDemo = New Table( "The Demographics",
 Add Rows( 2 ),
 New Column( "Patient ID",
  Character,
  "Nominal",
  Set Values( {"Patient A", "Patient B"} )
 ),
 New Column( "Age", Character( 16 ), "Nominal", Set Values( {"13", "15"} ) ),
 New Column( "Sex", Character( 16 ), "Nominal", Set Values( {"M", "F"} ) )
);

// Create a list with just the Patient IDs
summarize( dtData, theIDs = by( :Patient ID));
// Move it into a data table
dtIDs = New Table("theIDs", invisible, new column("Patient ID", character, values(theIDs)));

// Create a list with just the Diagnoses
summarize( dtData, theDiags = by( :Diagnosis));
// Move it into a data table
dtDiags = New Table("theDiags", invisible, new column("Diagnosis", character, values(theDiags)));

// Create a table with all possible combinations of patients and diagnoses
dtCart = dtIDs << Join( With( dtDiags ), Cartesian Join );

// Cleanup
close( dtIDs, nosave );
close( dtDiags, nosave);

// Add a null diagnosis column
dtCart << New Column("foundDiag", set each value(0));

dtData << New Column("foundDiag", set each value(1));

// Put the tables together
dtCart << Update(
 With( dtData),
 Match Columns( :Patient ID = :Patient ID, :Diagnosis = :Diagnosis )
);

// Split the data into the final form
dtSplit = dtCart << Split(
 Split By( :Diagnosis ),
 Split( :foundDiag ),
 Group( :Patient ID ),
 Sort by Column Property
);

// Make a copy of the demographics data table
dtFinal = dtDemo << subset( selected columns(0), selected rows(0));

// put the demographics file together with the split data table
dtFinal << Update(
 With( dtSplit ),
 Match Columns( :Patient ID = :Patient ID )
);

// Cleanup
close( dtSplit, nosave );
close( dtCart, nosave );