462295_de-DE

liliconcom

Spalten nach einer Liste von Werten aus einer anderen Spalte gruppieren?

Ich arbeite daran, mehrere tausend Spalten nach Namen zusammenzufassen, die mit etwas aus einer Liste von Werten aus einer Anfangsspalte übereinstimmen

 

Beispiel:

Col1-Werte = {step1, step2, step3}

Col2:5000 Namen: step1_blahblahblah, step2_blahblbahblah usw

 

Ich glaube, ich bin mir nicht ganz sicher, wie ich die if(contain)-Anweisung definieren soll, die die Werteliste von Col1 verwendet.

 

dt = current data table();
Summarize( dt, StepIDIndex= by( :RecipeStepId) );//get list of unique RecipeStepID's
colNamesList = dt << get column names(string, continuous);  //get all the column names
StepList = {}; //Create an empty list for the matching columns

// Find matching column names
For( i = 1, i <= N Items( colNamesList ), i++,
 If( 
  contains( colNamesList[i], StepIDIndex),
  Insert Into( StepList , colNamesList[i] )
 )
);

// If groups of columns are found, create col groupings
If( N Items( StepList ) > 0,
 dt<< select columns( StepList );
 dt<< group columns();
);

 

 

SkripterstellungBetreff: Spalten nach einer Liste von Werten aus einer anderen Spalte gruppieren?

Wenn Ihre Spaltennamen (?) immer das Format step1_something haben, können Sie Word verwenden, um den Schritt vom Rest der Zeichenfolge zu trennen, um den Vergleich zu erleichtern. Unten ist ein Beispiel dafür, was Sie meiner Meinung nach tun möchten (erfordert JMP16 aufgrund von For Each):

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(3),
 Set Header Height(44),
 New Column("Col1", Character, "Nominal", Set Values({"step1", "step2", "step3"})),
 New Column("step1_a", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("step1_b", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("step1_c", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("step2_a", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("step2_b", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .]))
);

Summarize(dt, uniq_vals = by(:col1)); 
col_list = dt << get column names(string, continuous);

//initialize col group collector associative array
col_groups = Repeat({{}}, N Items(uniq_vals));

For Each({col_name}, col_list,
 found_idx = Contains(uniq_vals, Word(1, col_name, "_"));
 If(found_idx,
  Insert Into(col_groups[found_idx], col_name);
 );
);

For Each({col_group, idx}, uniq_vals,
 If(N Items(col_groups[idx]) > 0,
  Eval(EvalExpr(dt << Group Columns(col_group, Expr(col_groups[idx]))));
 );
);