461858_it-IT

liliconcom

Cicli annidati con caselle di riepilogo

Sto cercando di costruire una matrice 2D con 2 cicli FOR nidificati utilizzati nel mouse sulle etichette al passaggio del mouse (Generatore di grafici -> Editor di etichette al passaggio del mouse -> Graphlet).

Fornisco qui un esempio semplificato per la matrice 2*2.

 

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
);
vlb << get picture;

Lo script sopra restituisce un output errato:

 

 

Per ottenere un risultato corretto, ho bisogno in qualche modo di ripristinare la casella di riepilogo H. Tuttavia, se aggiungo hlb << Set Items({}); come di seguito, il risultato è molto simile a quello sopra (cioè non corretto).

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
 <FONT color="#FF0000">hlb << Set Items({});</FONT>
);
vlb << get picture;

Ho anche provato a eliminare e ricreare la casella di riepilogo H come di seguito. Neanche questo funziona in quanto elimina l'oggetto Casella di riepilogo H già inserito nella casella di riepilogo V

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
<FONT color="#FF0000"> hlb << Delete;
 hlb  = H List Box();</FONT>
);
vlb << get picture;

Altri consigli? La mia versione di JMP è 16.2

 

Grazie;

Janne

GraficaSceneggiaturaRe: loop nidificati con caselle di riepilogo

Credo che questo sia quello che vuoi

vlb = V List Box();

For( row = 1, row <= 2, row++,
 hlb = H List Box();
 For( col = 1, col <= 2, col++,
  hlb << append( Text Box( "Row: " || Char( row ) || ", Col: " || Char( col ) ) )
 );
 vlb << append( hlb );
);
New Window( "show", vlb << get picture );

 

Re: loop nidificati con caselle di riepilogo

Puoi anche usare Table Box o Lineup Box con N Col:

Names Default To Here(1);

vlb = V List Box();

For(row = 1, row <= 2, row++,
 hlb = H List Box();
 For(col = 1, col <= 2, col++,
  hlb << append(Text Box("Row: " || Char(row) || ", Col: " || Char(col) || " || "))
 );
 vlb << append(hlb);
);

lb = Lineup Box(N Col(2));

cols = 2;
rows = 2;
For(i = 1, i <= cols * rows, i++,
 row = Ceiling(i / 2);
 col = !Modulo(i, 2) + 1; //just some calculation which works in this case
 Show(col);
 lb << append(Text Box("Row: " || Char(row) || ", Col: " || Char(col) || " || "));
);

//one option
tb = Table Box("",
 String Col Box("row1", {"Row: 1", "Row: 2"}),
 String Col Box("col1", {"Col: 1", "Col: 1"}),
 String Col Box("row1", {"Row: 1", "Row: 2"}),
 String Col Box("col1", {"Col: 2", "Col: 2"}),
);

New Window("",
 Lineup Box(N Col(1), 
  Text Box("V List Box"), 
  vlb,
  Text Box("Lineup"), 
  lb,
  Text Box("Table Box"), 
  tb
 )
);

Re: loop nidificati con caselle di riepilogo

Ciao,

 

Jim: Grazie per la tua soluzione. Funziona bene. Ora capisco perché le mie prove non hanno avuto successo.

Jarmo: Grazie per il tuo suggerimento per una soluzione alternativa da utilizzare Riquadro da tavolo o Riquadro di formazione; molto educativo.

 

Janne