461858_zh-CN

liliconcom

带有列表框的嵌套循环

我正在尝试构建一个带有 2 个嵌套 FOR 循环的 2D 矩阵，用于鼠标悬停标签（图形生成器 -> 悬停标签编辑器 -> Graphlet）。

我在这里提供了一个 2*2 矩阵的简化示例。

 

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
);
vlb << get picture;

上面的脚本导致错误的输出：

 

 

为了得到正确的结果，我需要以某种方式重置 H 列表框。 但是，如果我添加 hlb << Set Items({});如下所示，结果与上面非常相同（即不正确）。

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
 <FONT color="#FF0000">hlb << Set Items({});</FONT>
);
vlb << get picture;

我还尝试删除并重新创建 H 列表框，如下所示。 这也不起作用，因为它删除了已经馈入 V 列表框的 H 列表框对象

hlb  = H List Box();
vlb  = V List Box();

For (row=1, row<=2, row++,
 For (col=1, col<=2, col++,
  hlb << append(Text Box("Row: "|| char(row) ||", Col: "|| char(col) ))
  );
 vlb << append(hlb);
<FONT color="#FF0000"> hlb << Delete;
 hlb  = H List Box();</FONT>
);
vlb << get picture;

有什么进一步的建议吗？ 我的 JMP 版本是 16.2

 

谢谢;

珍妮

图形脚本回复：带有列表框的嵌套循环

我相信这就是你想要的

vlb = V List Box();

For( row = 1, row <= 2, row++,
 hlb = H List Box();
 For( col = 1, col <= 2, col++,
  hlb << append( Text Box( "Row: " || Char( row ) || ", Col: " || Char( col ) ) )
 );
 vlb << append( hlb );
);
New Window( "show", vlb << get picture );

 

回复：带有列表框的嵌套循环

您还可以使用带有 N Col 的 Table Box 或 Lineup Box：

Names Default To Here(1);

vlb = V List Box();

For(row = 1, row <= 2, row++,
 hlb = H List Box();
 For(col = 1, col <= 2, col++,
  hlb << append(Text Box("Row: " || Char(row) || ", Col: " || Char(col) || " || "))
 );
 vlb << append(hlb);
);

lb = Lineup Box(N Col(2));

cols = 2;
rows = 2;
For(i = 1, i <= cols * rows, i++,
 row = Ceiling(i / 2);
 col = !Modulo(i, 2) + 1; //just some calculation which works in this case
 Show(col);
 lb << append(Text Box("Row: " || Char(row) || ", Col: " || Char(col) || " || "));
);

//one option
tb = Table Box("",
 String Col Box("row1", {"Row: 1", "Row: 2"}),
 String Col Box("col1", {"Col: 1", "Col: 1"}),
 String Col Box("row1", {"Row: 1", "Row: 2"}),
 String Col Box("col1", {"Col: 2", "Col: 2"}),
);

New Window("",
 Lineup Box(N Col(1), 
  Text Box("V List Box"), 
  vlb,
  Text Box("Lineup"), 
  lb,
  Text Box("Table Box"), 
  tb
 )
);

回复：带有列表框的嵌套循环

你好，

 

吉姆：感谢您的解决方案。 它运作良好。 我现在明白为什么我的试验没有成功。

Jarmo：感谢您对使用替代解决方案的建议表盒或阵容盒；很有教育意义。

 

珍妮