459192_zh-CN

liliconcom

ppt中如何将控制图及其摘要保存到同一张幻灯片中

你好，

我有脚本可以根据参数创建具有功能的控制图块，我想将每个参数的每个报告保存到单独的 ppt 幻灯片中。 任何帮助表示赞赏。

以下是图表：

我想要每个参数图表并在单独的 ppt 幻灯片上报告：

 

附件是带有控制图脚本的表格。

 

谢谢，

托马斯

 

附言。如果可以只保存 Ppk 低于 1.33 的图表，那就太棒了:)

内容组织大规模定制质量与工艺工程Re: 如何将控制图及其摘要保存到ppt中的同一张幻灯片中

嗨，吉姆，

 

这正是我所需要的，非常感谢。

 

托马斯

Re: 如何将控制图及其摘要保存到ppt中的同一张幻灯片中

将下面的 JSL 添加到脚本的底部，你应该得到你想要的

nw = New Window( "Control Charts", 
 V List Box(
  obAge = Outline Box( "Control Chart for Age" ),
  obWeight = Outline Box( "Control Chart for Weight" ),
  obOxy = Outline Box( "Control Chart for Oxy" )
 )
);

ob = Outline Box( "", hlb = H List Box() );
hlb << append( Report( gb )["Levey Jennings of Age"] );
ob2 = Outline Box( "Distributions" );
ob2 << append( Report( gb )["Age"] );
hlb << append( ob2 );
obAge << append( ob << get picture );

ob = Outline Box( "", hlb = H List Box() );
hlb << append( Report( gb )["Levey Jennings of Weight"] );
ob2 = Outline Box( "Distributions" );
ob2 << append( Report( gb )["Weight"] );
hlb << append( ob2 );
obWeight << append( ob << get picture );

ob = Outline Box( "", hlb = H List Box() );
hlb << append( Report( gb )["Levey Jennings of Oxy"] );
ob2 = Outline Box( "Distributions" );
ob2 << append( Report( gb )["Oxy"] );
hlb << append( ob2 );
obOxy << append( ob << get picture );

nw << Save Presentation( "$TEMP/jmp_example2.pptx" );
Open( "$TEMP/jmp_example2.pptx" );

nw << close window;

Re: 如何将控制图及其摘要保存到ppt中的同一张幻灯片中

嗨，吉姆，

这看起来非常好并且做得很好但是有没有办法做类似的工作但保持原始控制图脚本的完整性不变？

我正在从所有图表中提取功能，因此我需要将它们集中在一个块中。

我确实按照你在如何使用 JSL 将日志保存为 PPT（每张幻灯片 2 张图） ，有没有办法修改该脚本以与控制图脚本一起使用？

 

谢谢，

托马斯

Re: 如何将控制图及其摘要保存到ppt中的同一张幻灯片中

这个问题以前有人问过。这是我处理问题的方式的链接

如何使用 JSL 将日志保存为 PPT（每张幻灯片 2 张图）

 

这是一个完整的示例，使用您的数据创建您想要的输出

Names Default To Here( 1 );
nw = New Window( "Control Charts",
 ob1 = Outline Box( "Levey Jennings of Age" ),
 ob2 = Outline Box( "Levey Jennings of Weight" ),
 ob3 = Outline Box( "Levey Jennings of Oxy" )
);
cc1 = Control Chart(
 invisible,
 Sample Label( :Name ),
 KSigma( 3 ),
 Chart Col(
  :Age,
  Levey Jennings(
   Show Zones( 1 ),
   Shade Zones( 1 ),
   Test 1( 1 ),
   Test 2( 1 ),
   Test 5( 1 ),
   Test 6( 1 ),
   Test Beyond Limits( 1 )
  ),
  Capability(
   Distribution(
    Continuous Distribution(
     Column( :Age ),
     Quantiles( 0 ),
     Horizontal Layout( 1 ),
     Vertical( 0 ),
     Outlier Box Plot( 0 ),
     Normal Quantile Plot( 1 ),
     Process Capability(
      Use Column Property Specs,
      Process Capability Analysis(
       Nonconformance( 0 ),
       Histogram( 1, Show Within Sigma Density( 0 ) )
      )
     ),
     Customize Summary Statistics( Skewness( 1 ) )
    )
   )
  )
 )
);
cc2 = Control Chart(
 invisible,
 Sample Label( :Name ),
 KSigma( 3 ),
 Chart Col(
  :Weight,
  Levey Jennings(
   Show Zones( 1 ),
   Shade Zones( 1 ),
   Test 1( 1 ),
   Test 2( 1 ),
   Test 5( 1 ),
   Test 6( 1 ),
   Test Beyond Limits( 1 )
  ),
  Capability(
   Distribution(
    Continuous Distribution(
     Column( :Weight ),
     Quantiles( 0 ),
     Horizontal Layout( 1 ),
     Vertical( 0 ),
     Outlier Box Plot( 0 ),
     Normal Quantile Plot( 1 ),
     Process Capability(
      Use Column Property Specs,
      Process Capability Analysis(
       Nonconformance( 0 ),
       Histogram( 1, Show Within Sigma Density( 0 ) )
      )
     ),
     Customize Summary Statistics( Skewness( 1 ) )
    )
   )
  )
 )
);
cc3 = Control Chart(
 invisible,
 Sample Label( :Name ),
 KSigma( 3 ),
 Chart Col(
  :Oxy,
  Levey Jennings(
   Show Zones( 1 ),
   Shade Zones( 1 ),
   Test 1( 1 ),
   Test 2( 1 ),
   Test 5( 1 ),
   Test 6( 1 ),
   Test Beyond Limits( 1 )
  ),
  Capability(
   Distribution(
    Continuous Distribution(
     Column( :Oxy ),
     Quantiles( 0 ),
     Horizontal Layout( 1 ),
     Vertical( 0 ),
     Outlier Box Plot( 0 ),
     Normal Quantile Plot( 1 ),
     Process Capability(
      Use Column Property Specs,
      Process Capability Analysis(
       Nonconformance( 0 ),
       Histogram( 1, Show Within Sigma Density( 0 ) )
      )
     ),
     Customize Summary Statistics( Skewness( 1 ) )
    )
   )
  )
 )
);
ob1 << append( cc1 << get picture );
ob2 << append( cc2 << get picture );
ob3 << append( cc3 << get picture );

nw << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );