¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el conmutador de columnas?Estoy intentando volver a crear un gráfico de control similar al siguiente. Soy gráficos de control de Levey-Jennings con conmutador de columnas. El eje x es consistente y es un código de lote alfanumérico. Actualmente necesito ayuda para agregar las líneas de referencia azules verticales para los ID de lote. Idealmente, estas líneas permanecerían mientras me muevo por el conmutador de columnas.
Actualmente estoy en JMP 15.2.0 en Windows 10
¡Gracias!
ventanasRe: ¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el selector de columnas?También puede usar secuencias de comandos gráficas. Primero calcule los índices para las líneas de referencia que tiene y luego agregue el script gráfico con V Line:
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
ccb = dt << Control Chart Builder(
Size(528, 456),
Show Two Shewhart Charts(0),
Show Control Panel(0),
Show Limit Summaries(0),
Variables(Subgroup(:Sample), Y(:Pin)),
Chart(Points(Statistic("Average")), Limits(Sigma("Levey Jennings"))),
Column Switcher(:Pin, {:Pin, :Weight, :Weight 2})
);
//calculate indices for references
uniq_vals = Associative Array(dt[0, "Sample"]) << get keys;
ref_vals = {4, 5, 6, 8};
/*jmp16
ref_idx = Transform Each({ref_val}, ref_vals,
Contains(uniq_vals, ref_val) - 1
);
*/
//jmp15
ref_idx = [];
For(i = 1, i <= N Items(ref_vals), i++,
idx = Contains(uniq_vals, ref_vals[i]);
If(idx,
Insert Into(ref_idx, idx - 1);
)
);
//add reference lines as Graphic Script
rep = ccb << report;
framebox = rep[frame box(1)];
Eval(EvalExpr(framebox << Add Graphics Script(
Pen Size(1);
Pen Color("Blue");
V Line(Expr(Transpose(ref_idx)));
)));
Re: ¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el selector de columnas?El script que adjuntó agrega 5 líneas de referencia.Se colocarán en x valores de 1, 2, 3, 4, 5. Si desea colocarlos en diferentes ubicaciones, deberá actualizar el script con las ubicaciones adecuadas.
Mire la entrada Agregar línea de referencia en OSI para ver cómo funciona la sintaxis para las líneas de referencia.
Re: ¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el selector de columnas?Gracias, @tonya_mauldin . Pude hacer que el script se ejecutara sin ningún error; sin embargo, movió esos puntos de referencia al inicio de la gráfica de control; en lugar de integrarlos por completo. Tiene alguna idea sobre esto?
¡Gracias de nuevo!
Re: ¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el selector de columnas?Hola @BrandonP1092 ,
Además de lo que @tonya_mauldin ha sugerido, también podría considerar agregar Límites de especificación o Límites de control como metadatos a sus columnas. Haga clic derecho en su columna y seleccione Información de la columna. En el menú desplegable Propiedades de columna, seleccione la que sea adecuada para sus necesidades.
Después de ingresar los límites de especificación/control, puede seleccionar "Mostrar como líneas de referencia de gráfico" y cada vez que haga un gráfico, distribución, etc. con los datos, tendrá líneas azules delgadas para USL, LSL, y objetivo (si no falta).
Si es más avanzado y realiza muchas secuencias de comandos, puede automatizar este proceso utilizando la plataforma Analizar > Calidad y proceso > Administrar límites de especificaciones. Te hace la vida mucho más fácil si tienes que hacer esto mucho.
¡Espero que esto ayude!,
SD
Re: ¿Cómo agrego/hago que las líneas de referencia sean consistentes dentro de un gráfico de control con el selector de columnas?Aquí hay un ejemplo de algo similar que puede usar.
dt=Open("$SAMPLE_DATA/Cities.jmp");
Control Chart Builder(
Show Two Shewhart Charts( 0 ),
Variables( Subgroup( :Region ), Y( :"pop- m"n ) ),
Chart( Points( Statistic( "Average" ) ), Limits( Sigma( "Levey Jennings" ) ) ),
Column Switcher( :"pop- m"n, {:"pop- m"n, :POP, :Max deg. F Jan, :OZONE, :CO} ),
SendToReport(
Dispatch(
{},
"Region",
ScaleBox,
{Add Ref Line( 1, "Solid", "Blue", "", 1 ),
Add Ref Line( 2, "Solid", "Blue", "", 1 ),
Add Ref Line( 3, "Solid", "Blue", "", 1 )}
)
)
)
