456624_zh-TW

liliconcom

如何將列表寫入新數據表中的列？

我正在嘗試從滿足條件的列中提取元素列表。 我想將此列表寫入具有相同列名的數據表，以便跟踪我的行。 我想隨著時間的推移繼續附加到這個列表中。 例如：

 

p = :col_name[condition << get selected rows];

我想將此列表寫入具有相同列名的表並附加到該表。

 

謝謝。

數據表腳本視窗回复：如何將列表寫入新數據表中的列？

您是否已經擁有數據表，還是會在獲取行列表後生成？ 創建新列時，還應檢查原始列的數據類型和建模類型並保持相同（此處未完成）：

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Select Rows([1,2,3,10]);

col_name = "name";
p = Column(dt, col_name)[dt << get selected rows];

//create new table
dt_rows = New Table("collection",
 New Column(col_name, Character, "Nominal", Set Values(p))
);

//add to existing
col_name = "age";
p = Column(dt, col_name)[dt << get selected rows];
dt_rows << New Column(col_name, Numeric, "Ordinal", Set Values(p));

回复：如何將列表寫入新數據表中的列？

以下是一些關於我將如何進行的示例

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";

dtFinal = New Table( "Results", New Column( target ) );

// Generate some random selected rows
For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = dt << get selected rows;
 dtInt = New Table( "temp", invisible, New Column( target, set values( theRows ) ) );
 dtFinal = dtFinal << concatenate( dtInt, append to first table( 1 ) );
 Close( dtInt, nosave );
);

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";
theRows = [];

For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = theRows |/ (dt << get selected rows);
);

dtFinal = New Table( "Results", New Column( target, set values( theRows ) ) );