456624_es-ES

liliconcom

Re: ¿Cómo escribo una lista en una columna en una nueva tabla de datos?

Gracias. Esto es útil.

Re: ¿Cómo escribo una lista en una columna en una nueva tabla de datos?

Aquí hay un par de ejemplos de cómo procedería.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";

dtFinal = New Table( "Results", New Column( target ) );

// Generate some random selected rows
For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = dt << get selected rows;
 dtInt = New Table( "temp", invisible, New Column( target, set values( theRows ) ) );
 dtFinal = dtFinal << concatenate( dtInt, append to first table( 1 ) );
 Close( dtInt, nosave );
);

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";
theRows = [];

For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = theRows |/ (dt << get selected rows);
);

dtFinal = New Table( "Results", New Column( target, set values( theRows ) ) );

Re: ¿Cómo escribo una lista en una columna en una nueva tabla de datos?

¿Ya tiene la tabla de datos o la generará después de obtener la lista de filas? Cuando crea nuevas columnas, también debe verificar el tipo de datos y el tipo de modelado de la columna original y mantenerlos iguales (no se hace aquí):

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Select Rows([1,2,3,10]);

col_name = "name";
p = Column(dt, col_name)[dt << get selected rows];

//create new table
dt_rows = New Table("collection",
 New Column(col_name, Character, "Nominal", Set Values(p))
);

//add to existing
col_name = "age";
p = Column(dt, col_name)[dt << get selected rows];
dt_rows << New Column(col_name, Numeric, "Ordinal", Set Values(p));

¿Cómo escribo una lista en una columna de una nueva tabla de datos?

Estoy intentando extraer una lista de elementos de una columna que satisface una condición. Me gustaría escribir esta lista en una tabla de datos con el mismo nombre de columna para poder realizar un seguimiento de mis filas. Me gustaría seguir añadiendo a esta lista con el tiempo. Por ejemplo:

 

p = :col_name[condition << get selected rows];

Quiero escribir esta lista en una tabla con el mismo nombre de columna y agregarla a esta tabla.

 

Gracias.

La personalización en masaIngeniería de Calidad y Procesosventanas