456624_de-DE

liliconcom

Wie schreibe ich eine Liste in eine Spalte in einer neuen Datentabelle?

Ich versuche, eine Liste von Elementen aus einer Spalte zu extrahieren, die eine Bedingung erfüllt. Ich möchte diese Liste in eine Datentabelle mit demselben Spaltennamen schreiben, damit ich meine Zeilen verfolgen kann. Ich möchte diese Liste mit der Zeit immer weiter ergänzen. Beispielsweise:

 

p = :col_name[condition << get selected rows];

Ich möchte diese Liste in eine Tabelle mit demselben Spaltennamen schreiben und an diese Tabelle anhängen.

 

Danke.

DatentabelleSkripterstellungWindowsBetreff: Wie schreibe ich eine Liste in eine Spalte in einer neuen Datentabelle?

Haben Sie bereits die Datentabelle oder werden Sie sie generieren, nachdem Sie eine Liste der Zeilen erhalten haben? Wenn Sie neue Spalten erstellen, sollten Sie auch den Datentyp und den Modellierungstyp der ursprünglichen Spalte überprüfen und beibehalten (hier nicht ausgeführt):

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Select Rows([1,2,3,10]);

col_name = "name";
p = Column(dt, col_name)[dt << get selected rows];

//create new table
dt_rows = New Table("collection",
 New Column(col_name, Character, "Nominal", Set Values(p))
);

//add to existing
col_name = "age";
p = Column(dt, col_name)[dt << get selected rows];
dt_rows << New Column(col_name, Numeric, "Ordinal", Set Values(p));

Betreff: Wie schreibe ich eine Liste in eine Spalte in einer neuen Datentabelle?

Hier sind ein paar Beispiele, wie ich vorgehen würde

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";

dtFinal = New Table( "Results", New Column( target ) );

// Generate some random selected rows
For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = dt << get selected rows;
 dtInt = New Table( "temp", invisible, New Column( target, set values( theRows ) ) );
 dtFinal = dtFinal << concatenate( dtInt, append to first table( 1 ) );
 Close( dtInt, nosave );
);

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";
theRows = [];

For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = theRows |/ (dt << get selected rows);
);

dtFinal = New Table( "Results", New Column( target, set values( theRows ) ) );