456624_fr-FR

liliconcom

Re : Comment écrire une liste dans une colonne d'une nouvelle table de données ?

Merci. C'est utile.

Re : Comment écrire une liste dans une colonne d'une nouvelle table de données ?

Voici quelques exemples sur la façon dont je procéderais

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";

dtFinal = New Table( "Results", New Column( target ) );

// Generate some random selected rows
For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = dt << get selected rows;
 dtInt = New Table( "temp", invisible, New Column( target, set values( theRows ) ) );
 dtFinal = dtFinal << concatenate( dtInt, append to first table( 1 ) );
 Close( dtInt, nosave );
);

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

loop = 5;
target = "NPN1";
theRows = [];

For( i = 1, i <= loop, i++,
 Current Data Table( dt );
 For Each Row(
  If( Random Uniform( 1, 100 ) > 95,
   Row State( Row() ) = Selected State( 1 )
  )
 );
 theRows = theRows |/ (dt << get selected rows);
);

dtFinal = New Table( "Results", New Column( target, set values( theRows ) ) );

Re : Comment écrire une liste dans une colonne d'une nouvelle table de données ?

Avez-vous déjà la table de données ou allez-vous la générer après avoir obtenu la liste des lignes ? Lorsque vous créez de nouvelles colonnes, vous devez également vérifier le type de données et le type de modélisation de la colonne d'origine et les conserver (ce n'est pas fait ici) :

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Select Rows([1,2,3,10]);

col_name = "name";
p = Column(dt, col_name)[dt << get selected rows];

//create new table
dt_rows = New Table("collection",
 New Column(col_name, Character, "Nominal", Set Values(p))
);

//add to existing
col_name = "age";
p = Column(dt, col_name)[dt << get selected rows];
dt_rows << New Column(col_name, Numeric, "Ordinal", Set Values(p));

Comment écrire une liste dans une colonne d’une nouvelle table de données ?

J'essaie d'extraire une liste d'éléments d'une colonne qui satisfait une condition. J'aimerais écrire cette liste dans une table de données avec le même nom de colonne afin de pouvoir suivre mes lignes. J'aimerais continuer à ajouter à cette liste avec le temps. Par exemple:

 

p = :col_name[condition << get selected rows];

Je veux écrire cette liste dans une table avec le même nom de colonne et l'ajouter à cette table.

 

Merci.

Personnalisation de masseIngénierie Qualité et Procédésles fenêtres