1分の解像度（「タイムスタンプ-1分」）で2021年のタイムスタンプを持つメインテーブルがあります。 1年の各日の条件のペア（日の出、日の入り：薄明の開始と終了）に応じて、1日の解像度（「開始-終了-TS1」）で2番目のテーブルのデータをメインテーブルに入力する必要があります。日、月、[条件の時間（Hr：min）]。
「Timestamp-1min-Result」テーブルにある日付6/14 / 2021-に対して実行しました。
1つの列-"SStart-S End"-を追加しました。これはSunrise-Start、Sunrise-End、およびTwilight（StartとEnd）の別の列です。また、日長、Mid T、Twilight時間、およびコードを入力します。列（DT / TT）-後で参加する別のテーブルで統計を実行するのに役立つ日中/薄明時間。 2番目のテーブルから値を取得する代わりに、数式を使用して合計日時間とトワイライト時間（結果テーブル内）を設定するにはどうすればよいですか。 昼間のみ（DTとして）および薄明時間のみ（TTとして）のコードを作成するにはどうすればよいですか？
インタラクティブにそれを行う方法は？ またはJSLが唯一の方法ですか？
あなたが望むことをする唯一の効率的な方法は、JSLの一部を使用することです。複数の数式列を使用してこれを行うと、50万レコードを複数回読み取る必要があります。以下のJSLは、メインテーブルを1回だけ読み取ります。
また、これをすべて1つのテーブルで行うこともできますが、Excelを使用しているふりをして、すべてのデータをルックアップデータテーブルからメインテーブルに移動してから、列を非表示にする必要があります。かわいくないでしょう。これが、問題を解決するのに大いに役立つと思うスクリプトです。50万件のレコードがある場合、必要なすべての比較を行うには数分かかります。スクリプトは特定の名前の2つのデータテーブルを探していることに注意してください。
Names Default To Here( 1 );
dtMain = Data Table( "Timestamp-1min" );
dtLookUP = Data Table( "Start-End-TS1" );
// Add the required new colummns
dtMain << New Column( "S Start-S End", format("h:m:s"));
dtMain << New Column( "T Start-T End", format("h:m:s"));
dtMain << New Column( "Day Length", format("h:m:s"));
dtMain << New Column( "Mid T", format("h:m:s"));
dtMain << New Column( "Twilight time", format("h:m:s"));
dtMain << New Column( "DT/TT", character);
// Loop through Main table and set values
DT = "";
dl = twTime = .;
For( i = 1, i <= N Rows( dtMain ), i++,
If( i == 1 | Day( dtMain:Timestamp[i] ) != Day( dtMain:Timestamp[i - 1] ),
theRow = Try(
(dtLookUp << get rows where(
dtLookUp:Month 2 == Month( dtMain:Timestamp[i] ) & dtLookUp:Date == Day( dtMain:Timestamp[i] )
))[1],
.
)
);
// Get the time for the current row
theTime = Date MDY( 12, 31, 1899 ) + 3600 * Hour( dtMain:Timestamp[i] ) + 60 * Minute( dtMain:Timestamp[i] )
+Second( dtMain:Timestamp[i] );
theNextTime = Date MDY( 12, 31, 1899 ) + 3600 * Hour( dtMain:Timestamp[i + 1] ) + 60 *
Minute( dtMain:Timestamp[i + 1] ) + Second( dtMain:Timestamp[i + 1] );
// If this is a Twilight Start, record the time, and set the value for Twilight time
If( dtLookUp:Twilight start[theRow] >= theTime & dtLookUp:TwilightStart[theRow] <= theNextTime,
dtMain:"T Start-T End"n[i] = dtLookUp:Twilight start[theRow];
DT = "TT";
twTime = dtLookUp:Twilight Length[theRow];
);
// If this is Sunrise, recorde the time and set the value for Day Length
If( dtLookUp:Sunrise[theRow] >= theTime & dtLookUp:Sunrise[theRow] <= theNextTime,
dtMain:"S Start-S End"n[i] = dtLookUp:Sunrise[theRow];
DT = "DT";
dl = dtLookUp:Day Length[theRow];
);
// If sunset has ended record the value and blank out the day length time
If( dtLookUp:Sunset[theRow] >= theTime & dtLookUp:Sunset[theRow] <= theNextTime,
dtMain:"S Start-S End"n[i] = dtLookUp:Sunset[theRow];
DT = "TT";
dl = .;
);
// If twighlight has ended record the value and blank out the Twilight time
If( dtLookUp:Twilight End[theRow] >= theTime & dtLookUp:Twilight End[theRow] <= theNextTime,
dtMain:"T Start-T End"n[i] = dtLookUp:Twilight End[theRow];
DT = "";
twTime = .;
);
// If this is the Mid T time, record the value
If( dtLookUp:Mid T[theRow] >= theTime & dtLookUp:Mid T[theRow] <= theNextTime,
dtMain:Mid T[i] = dtLookUp:Mid T[theRow]
);
// Write the repeating values
dtMain:"DT/TT"n[i] = DT;
dtMain:Twilight time[i] = twTime;
dtMain:Day Length[i] = dl;
// Do some cleanup on ending records
If( Is Missing( dtMain:"S Start-S End"n[i] ) == 0 & Is Missing( dtMain:Day Length[i - 1] ) == 0,
dtMain:Day Length[i] = dtMain:Day Length[i - 1]
);
If( Is Missing( dtMain:"T Start-T End"n[i] ) == 0 & Is Missing( dtMain:Twilight time[i - 1] ) == 0,
dtMain:Twilight time[i] = dtMain:Twilight time[i - 1]
);
If( Is Missing( dtMain:Twilight time[i] ) == 0 & dtMain:"DT/TT"n[i] == "",
dtMain:"DT/TT"n[i] = dtMain:"DT/TT"n[i - 1]
);
);
ネルソン、
すばらしい！ どうもありがとう！！！
スクリプトの練習をどこから始めればよいかを知る必要があります。 従うことができる基本的なスクリプトの例とDIYはありますか？
