450420_it-IT

liliconcom

Estrai il testo dalla stringa

Ciao,

Se possibile vorrei estrarre un testo particolare dalle stringhe:

\\swirt.misc@CAS-K-CLERK\K10447-Wit_OG lo hi TT-YYT (CTL1083.1)_172-7-10053 -303

\\swirt.misc@CAS-K-CLERK\K10445-Wit_OG lo hi ES WERT (CIL0858.1)_172-7-10046-600

\\swirt.misc@CAS-K-CLERK\K10437-Wit_OG lo hi TT-YYT (CTL1077.1)_172-7-10053-303

\\swirt.misc@CAS-K-CLERK\K10420-Wit_OG lo hi ES TRTR (CMA0851.1)_172-7-10047-600

\\swirt.misc@CAS-K-CLERK\K10377-Wit_OG_lo hi_ES_SI (CMS0499.1)_ 172-7-10041-600

\\swirt.misc@CAS-K-CLERK\K10451-Wit_OG lo ciao TT-YYT (CTL1078

\\swirt.misc@CAS-K-CLERK\K10468-Wit_OG lo hi YYT DEV-020856 (CTLR1073

\\swirt.misc@CAS-K-CLERK\K10022 -Wit_OG lo hi YYT DEV-020414 (CTLR0999.1)

\\swirt.misc@CAS-K-CLERK\K10030-Wit_OG lo ciao TT-YYT (CTL1008.1)

 

e voglio estrarre gli ID dall'alto:

CTL1083.1

CIL0858.1

CTL1077.1

CMA0851.1

CMS0499.1

CTL1078

CTLR1073

CTLR0999.1

CTL1008.1

 

Qualsiasi aiuto apprezzato.

Grazie,

Tomasz

 

 

 

 

SceneggiaturaRe: Estrarre il testo dalla stringa

Utilizzare la funzione PAROLE con ( e ) come delimitatori.Utilizzare il secondo elemento nell'elenco restituito.Esegui il codice seguente e controlla l'output nella finestra di registro.

dt = New Table( "Test Words", Add Rows( 9 ),
 New Column( "Column 1", Character, "Nominal",
  Set Values(
   {
   "\\swirt.misc@CAS-K-CLERK\K10447-Wit_OG lo hi TT-YYT (CTL1083.1)_172-7-10053 -303",
   "\\swirt.misc@CAS-K-CLERK\K10445-Wit_OG lo hi ES WERT (CIL0858.1)_172-7-10046-600",
   "\\swirt.misc@CAS-K-CLERK\K10437-Wit_OG lo hi TT-YYT (CTL1077.1)_172-7-10053-303",
   "\\swirt.misc@CAS-K-CLERK\K10420-Wit_OG lo hi ES TRTR (CMA0851.1)_172-7-10047-600",
   "\\swirt.misc@CAS-K-CLERK\K10377-Wit_OG_lo hi_ES_SI (CMS0499.1)_ 172-7-10041-600",
   "\\swirt.misc@CAS-K-CLERK\K10451-Wit_OG lo hi TT-YYT (CTL1078",
   "\\swirt.misc@CAS-K-CLERK\K10468-Wit_OG lo hi YYT DEV-020856 (CTLR1073",
   "\\swirt.misc@CAS-K-CLERK\K10022 -Wit_OG lo hi YYT DEV-020414 (CTLR0999.1)",
   "\\swirt.misc@CAS-K-CLERK\K10030-Wit_OG lo hi TT-YYT (CTL1008.1)"}
  ),
  Set Display Width( 583 )
 )
);

for (i = 1, i <= nrows(dt), i++,
 one_value = dt:column 1[i];
 
 word_list = words(one_value, "()");
 print(word_list[2]);
);

Re: Estrarre il testo dalla stringa

La soluzione da @pmroz è molto robusto, bello!

Un approccio leggermente diverso potrebbe essere quello di utilizzare le formule nella tabella dei dati

 

 

 La posizione del delimitatore di inizio potrebbe essere individuata con un argomento "Contiene".

Contains(:text, "(")

La posizione del delimitatore finale potrebbe trovarsi allo stesso modo

Contains( :text, ")" )

Un argomento oscuro ma davvero divertente, "munger", potrebbe essere utilizzato per estrarre la stringa tra le posizioni del delimitatore.

In questo caso vogliamo la stringa dopo il carattere delimitatore, che termina prima del carattere delimitatore finale, quindi 1 viene aggiunto all'inizio e sottratto dalla fine.

La funzione per munger in questo caso utilizza gli argomenti, testo intero, da dove iniziare, quanti caratteri restituire. Munger può anche fare altre cose interessanti, come trova e sostituisci.

Munger( :text, :start + 1, (:stop - :start) - 1 )

Avvolgere tutto ciò in una formula sarebbe simile a questo

Munger(
 :text,
 Contains( :text, "(" ) + 1,
 (Contains( :text, ")" ) - Contains( :text, "(" )) - 1
)

 

 

 

Re: Estrarre il testo dalla stringa

Io uso SOTTOSTR per effetto simile.

for (i = 1, i <= nrows(dt), i++,
 one_value = dt:column 1[i];
 start  = contains(one_value, "(") + 1;
 end    = contains(one_value, ")") - 1;
 len    = end - start + 1;
 result = substr(one_value, start, len);
 print(result);
);

Re: Estrarre il testo dalla stringa

Nel caso ti piacciano le espressioni regolari...

 

Names Default to Here( 1 );

// make list of example original strings
sample = "\\swirt.misc@CAS-K-CLERK\K10447-Wit_OG lo hi TT-YYT (CTL1083.1)_172-7-10053 -303

\\swirt.misc@CAS-K-CLERK\K10445-Wit_OG lo hi ES WERT (CIL0858.1)_172-7-10046-600

\\swirt.misc@CAS-K-CLERK\K10437-Wit_OG lo hi TT-YYT (CTL1077.1)_172-7-10053-303

\\swirt.misc@CAS-K-CLERK\K10420-Wit_OG lo hi ES TRTR (CMA0851.1)_172-7-10047-600

\\swirt.misc@CAS-K-CLERK\K10377-Wit_OG_lo hi_ES_SI (CMS0499.1)_ 172-7-10041-600

\\swirt.misc@CAS-K-CLERK\K10451-Wit_OG lo hi TT-YYT (CTL1078

\\swirt.misc@CAS-K-CLERK\K10468-Wit_OG lo hi YYT DEV-020856 (CTLR1073

\\swirt.misc@CAS-K-CLERK\K10022 -Wit_OG lo hi YYT DEV-020414 (CTLR0999.1)

\\swirt.misc@CAS-K-CLERK\K10030-Wit_OG lo hi TT-YYT (CTL1008.1)";
sample = Words( sample, "\!U000D" );
// Show( sample );
n = N Items( sample );

id = List();

// iterate over list and return target strings
For Each( { string }, sample,
 If( Contains( string, ")" ),
  Insert Into( id, Regex( string, "(.+\()(.+)(\).*)", "\2" ) ),
  Insert Into( id, Regex( string, "(.+\()(.+)",       "\2" ) )
 );
);

Show( id );

Re: Estrarre il testo dalla stringa

Mi piace la funzione "Word()" per tali estrazioni di stringhe

Names Default To Here( 1 );
dt = New Table( "Test Words",
 Add Rows( 9 ),
 New Column( "Column 1",
  Character,
  "Nominal",
  Set Values(
   {"\\swirt.misc@CAS-K-CLERK\K10447-Wit_OG lo hi TT-YYT (CTL1083.1)_172-7-10053 -303",
   "\\swirt.misc@CAS-K-CLERK\K10445-Wit_OG lo hi ES WERT (CIL0858.1)_172-7-10046-600",
   "\\swirt.misc@CAS-K-CLERK\K10437-Wit_OG lo hi TT-YYT (CTL1077.1)_172-7-10053-303",
   "\\swirt.misc@CAS-K-CLERK\K10420-Wit_OG lo hi ES TRTR (CMA0851.1)_172-7-10047-600",
   "\\swirt.misc@CAS-K-CLERK\K10377-Wit_OG_lo hi_ES_SI (CMS0499.1)_ 172-7-10041-600",
   "\\swirt.misc@CAS-K-CLERK\K10451-Wit_OG lo hi TT-YYT (CTL1078",
   "\\swirt.misc@CAS-K-CLERK\K10468-Wit_OG lo hi YYT DEV-020856 (CTLR1073",
   "\\swirt.misc@CAS-K-CLERK\K10022 -Wit_OG lo hi YYT DEV-020414 (CTLR0999.1)",
   "\\swirt.misc@CAS-K-CLERK\K10030-Wit_OG lo hi TT-YYT (CTL1008.1)"}
  ),
  Set Display Width( 583 )
 )
);

For( i = 1, i <= N Rows( dt ), i++,
 Print( Word( 2, dt:column 1[i], "()" ) )
);

Re: Estrarre il testo dalla stringa

@pmroz , il tuo codice sembra sempre molto meno casuale del mio ; )

Substring (substr) è un approccio più semplice, non riesco proprio a resistere a un buon caso per munger.

 

Craig Hales probabilmente ha degli approcci ancora più efficienti usando il pattern matching. Sono sicuro che ci sono già degli esempi nelle pagine della community o nel suo blog.

Re: Estrarre il testo dalla stringa

Wow, un sacco di modi per affettare una pagnotta in JMP.

Re: Estrarre il testo dalla stringa

molto bello, tutti i suggerimenti fanno la magia.

 

Ho usato Munger nella mia sceneggiatura e funziona perfettamente.

 

Molte grazie

Tomasz