JSL을 사용하여 특정 열에 두 가지를 적용하고 싶습니다.
1. " "를 기준으로 첫 번째 알파벳을 대문자로 시작합니다.
(시험, ple -> 시험, Ple , JSL TEST -> Jsl 테스트)
2. ","가 있는 경우
행 복제 있도록 "," 앞의 단어를 사용하는 한 행과 "," 뒤의 단어로 한 행 ","를 기준으로 합니다.
예를 들어:
- Column1 - "exa, ple"이 첫 번째 행에 입력되고,
- 이것을 "시험, 플레"로 교체하십시오.
- 이것을 2행으로 만들고 Column2, Column3의 값을 그대로 복사합니다.
위의 두 가지 규칙을 Column에 적용하는 스크립트를 알려주시면 정말 감사하겠습니다.
미리 감사합니다! 코로나19 조심하시기 바랍니다.
첫 번째 작업은 Titlecase()로 수행할 수 있습니다. 예를 들어 For Each를 사용하여 행을 반복하거나 JMP에서 직접 대화식으로 두 번째 작업을 수행할 수 있습니다.
대화형 솔루션:
1. 시작 테이블
2. Col_a를 선택하고 Cols / Utilities / Text to Columns로 이동하여 구분 기호로 , 사용
3. 다음으로 테이블/스택으로 이동합니다. 다음과 같은 설정으로 시작하여 시도해 보십시오.
결과 테이블:
4. 레이블 열 삭제 및 데이터 열의 빈 행 중 하나 선택 -> 마우스 오른쪽 버튼 클릭 -> 일치하는 셀 선택 -> 행 삭제
스크립팅을 사용하면 예를 들어 이와 같은 작업을 수행할 수 있습니다(For Each로 인해 JMP16이 필요하지만 필요한 경우 For-loop으로 변경할 수 있음). 이것은 또한 행을 복제하는 데 사용되는 문자열에 얼마나 많은 열이 있고 얼마나 많은 값이 있을 수 있는지 알고 있으면 더 간단하게 만들 수 있습니다.
Names Default To Here(1);
dt = New Table("Untitled",
Add Rows(2),
New Column("Col_a", Character, "Nominal", Set Values({"exam, ple", "JSL TEST"})),
New Column("Col_b", Numeric, "Continuous", Format("Best", 12), Set Values([123, 345])),
New Column("Col_3", Numeric, "Continuous", Format("Best", 12), Set Values([222, 333]))
);
Column(dt, "Col_a") << Set Each Value(Titlecase(:Col_a));
//using collector table:
dt_collector = dt << Subset(
Rows([1]),
Selected columns only(0)
);
dt_collector << Delete Rows([1]);
For Each Row(dt,
row_vals = dt[Row(), 0];
If(Contains(row_vals[1], ","),
new_items = Words(row_vals[1], ",");
For Each({new_item}, new_items,
dt_collector << Add Row(1);
row_to_add = Insert(Eval List({Trim Whitespace(new_item)}), Remove(row_vals, 1));
dt_collector[N Rows(dt_collector), 0] = row_to_add;
);
, //else
dt_collector << Add Row(1);
dt_collector[N Rows(dt_collector), 0] = row_vals;
);
);
//adding to same table
//get rows with ,
rows_to_add = dt << Get Rows Where(Contains(:Col_a, ","));
For Each({new_row}, rows_to_add,
new_items = Words(dt[new_row, "Col_a"], ",");
dt[new_row, "Col_a"] = Trim Whitespace(new_items[1]);
Remove From(new_items, 1);
For Each({new_item}, new_items,
dt << Add Rows(1);
row_to_add = Insert(Eval List({Trim Whitespace(new_item)}), Remove(dt[new_row, 0], 1));
dt[N Rows(dt_collector), 0] = row_to_add;
);
show(new_items);
);
굉장해.. 쯧쯧!!!!
당신이 제안한 스크립트는 두 가지 문제를 완전히 해결했습니다.
매우 감사합니다.
새해 복 많이 받으시기 바랍니다 
스크립트는 두 가지 문제를 모두 해결하지만 일반적으로 JMP에서도 대화식으로 수행하는 것이 좋습니다. Recode 플랫폼을 통해 JMP에서 Titlecase를 수행하도록 할 수도 있습니다.
또는 새 수식 열 만들기:
그리고 JMP16에서 수행하는 몇 가지 작업을 통해 향상된 로그에서 쉽게 프로세스를 자동화할 수 있습니다.
