443181_es-ES

liliconcom

¿Cómo puedo configurar la orientación de las etiquetas en el eje horizontal del histograma de distribución para que sea perpendicular a todos los histogramas?

Estoy tratando de cambiar la orientación de las etiquetas y el formato (Ingeniería SI) para el eje horizontal en los diagramas de Distribución (histogramas). Puedo hacerlo para el primero usando una declaración de despacho dentro de la expresión que estoy construyendo, pero necesito poder hacerlo para todos los histogramas en la lista de columnas.

Intenté insertar diferentes tipos de llamadas al nombre de la columna entre "{}" en:

Envío ({},

pero ninguno hace que los histogramas cambien. Funciona si pongo literalmente el nombre de la columna (es decir, {"Mi columna"}) solamente, pero quiero que lo haga para todos los nombres en la matriz colList.

 

dt = currentdatatable();

col = dt << get column names();
nc = N Items( col );
colList = {};
bin_width={};

For( i = 1, i <= nc, i++,
 If(Contains (col[i],"::"),
 Insert Into( colList, col[i] ))
);


For(i = 1, i <= N Items(colList), i++,
 Insert Into(bin_width,0.0);
 bin_width[i] = Col Max(Column(dt, colList[i])) - Col Min(Column(dt, colList[i]));
 bin_width[i] = bin_width[i]/10;
);


theExpr = "dis = dt << Distribution(Stack( 1 ),
 Continuous Distribution( column( column(dt,colList[1])), Set Bin Width(bin_width[1]), Label Row( Label Orientation( \!"Perpendicular\!" ) ))
 ";

For( i = 2, i < N Items( colList ), i++,
 theExpr = theExpr || ", Continuous Distribution( column( column(dt, colList[" || Char( i ) || "])), Set Bin Width(bin_width[i]))"
);


theExpr = theExpr || ",
 SendToReport(
  Dispatch(
   {},
   \!"1\!",
   ScaleBox,
   {Format( \!"Engineering SI\!", 10 ), Minor Ticks( 0 ),
   Label Row( Label Orientation( \!"Perpendicular\!" ) )}
  )
);";

Eval( Parse( theExpr ) );

ScriptingRe: ¿Cómo puedo configurar la orientación de las etiquetas en el eje horizontal del histograma de distribución para que sea perpendicular a todos los histogramas?

Este es el enfoque que tomaría

dt = currentdatatable();

col = dt << get column names();
nc = N Items( col );
colList = {};
bin_width={};

For( i = 1, i <= nc, i++,
 If(Contains (col[i],"::"),
 Insert Into( colList, col[i] ))
);

For(i = 1, i <= N Items(colList), i++,
 Insert Into(bin_width,0.0);
 bin_width[i] = Col Max(Column(dt, colList[i])) - Col Min(Column(dt, colList[i]));
 bin_width[i] = bin_width[i]/10;
);


theExpr = "dis = dt << Distribution(Stack( 1 ),
 Continuous Distribution( column( column(dt,colList[1])), Set Bin Width(bin_width[1]), Label Row( Label Orientation( \!"Perpendicular\!" ) ))
 ";

For( i = 1, i < N Items( colList ), i++,
 theExpr = theExpr || ", Continuous Distribution( column( column(dt, colList[" || Char( i ) || "])), Set Bin Width(bin_width[i]))"
);

Eval( Parse( theExpr ) );

(dis << xpath("//AxisBox")) << format("Engineering SI", 10);
(dis << xpath("//AxisBox")) << Minor Ticks( 0 );
(dis << xpath("//AxisBox")) << Label Row( Label Orientation( "Perpendicular" ));

Re: ¿Cómo puedo configurar la orientación de las etiquetas en el eje horizontal del histograma de distribución para que sea perpendicular a todos los histogramas?

Gracias Jim que funcionó a la perfección