How to get Kaiser's MSA (aka KMO) in JMP's Factor analysis?

goutam

The Kaiser's MSA (also called KMO) is a metric that is frequently used along with anti-image correlation matrix to judge the suitability of a set of variables for factor analsysis. I can get these easily uisng SAS (proc factor). Anyone knwos how to get these in JMP (I am using JMP Pro version 9)?  I see there was a post in early 2010 about KMO and the answer there was to literally calculate these by exporting the partial/inverse correlation matric to Excel. I am hoping by now, JMP or soem users have come up with a script or some options that do it automatically. Thanks.

mpb

See if this code is helpful. I only was able to check it against the socioeconomic sample data and the results were same as the SAS results shown in the SAS docs online. Use at your own risk and certainly test on as many datasets as you have MSA results for.

 

 

/* Next line if want to open a specific JMP table */
//dt = Open( "$SAMPLE_DATA/Socioeconomic.jmp" );
/* Next line if want to have user pick a JMP data table */
//dt = Open();
/* No Open statement if want to run against the current data table */

cd = Column Dialog( Col ID = ColList( "Select Columns" ) );

names = cd["Col ID"];
nsel = N Items( names );

mv = Multivariate(
    Y( Eval( names ) ),
    Estimation Method( "Row-wise" ),
    Scatterplot Matrix( Density Ellipses( 1 ), Shaded Ellipses( 0 ), Ellipse Color( 3 ) ),
    Partial Correlations( 1 )
);

rmv = Report( mv );

dtcorr = rmv["Correlations"][Matrix Box( 1 )] << make into data table;
dtpart = rmv["Partial Corr"][Matrix Box( 1 )] << make into data table;

stkcorr = dtcorr << Stack(
&nbsp;&nbsp;&nbsp; columns( Eval( names ) ),
&nbsp;&nbsp;&nbsp; Source Label Column( "Label" ),
&nbsp;&nbsp;&nbsp; Stacked Data Column( "Data" )
);

stkpart = dtpart << Stack(
&nbsp;&nbsp;&nbsp; columns( Eval( names ) ),
&nbsp;&nbsp;&nbsp; Source Label Column( "Label" ),
&nbsp;&nbsp;&nbsp; Stacked Data Column( "Data" )
);

Close( dtcorr, nosave );
Close( dtpart, nosave );

stkcorr << New Column( "DataSqr", formula( Data ^ 2 ) );
stkpart << New Column( "DataSqr", formula( Data ^ 2 ) );

sumsqrcorr = Col Sum( (stkcorr:"DataSqr") ) - nsel;
sumsqrpart = Col Sum( (stkpart:"DataSqr") );

MSA = sumsqrcorr / (sumsqrcorr + sumsqrpart);

//Show( MSA );

Summarize( bycorr = by( stkcorr:"Row" ), sumsqrcorrby = Sum( stkcorr:"DataSqr" ) );
Summarize( bypart = by( stkpart:"Row" ), sumsqrpartby = Sum( stkpart:"DataSqr" ) );

Close( stkcorr, nosave );
Close( stkpart, nosave );

//show(sumsqrcorrby, sumsqrpartby);
//show(bycorr, bypart);

sumsqrcorrby = sumsqrcorrby - 1;
//show(sumsqrcorrby);
MSAvar = {};
For( i = 1, i <= nsel, i++,
&nbsp;&nbsp;&nbsp; MSAvar = sumsqrcorrby / (sumsqrcorrby + sumsqrpartby);
&nbsp;&nbsp;&nbsp; //Show( bycorr, MSAvar );
);

sr = New Window( "Summary Results",
&nbsp;&nbsp;&nbsp; V List Box(
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp; Table Box( String Col Box( "Variable", bycorr ), Number Col Box( "MSA", MSAvar ) ),
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp; Text Box( "Overall MSA = " || Char( round(MSA, 5) ) )
&nbsp;&nbsp;&nbsp; )
);