442077_it-IT

liliconcom

Problema con la tabella di ricerca / Loc ordinato

Sto cercando di trovare il momento in cui il valore misurato è la metà in questa tabella di dati. Il mio output desiderato sarebbe una tabella riassuntiva con il tempo a metà misurazione per campione.

 

 

Questa è la tabella estiva generata dallo script e come puoi vedere il tempo a metà misura non è corretto.

 

 

Ho creato il seguente script che utilizza Loc ordinato per cercare i valori da questa tabella, ma ho difficoltà a farlo funzionare. Ci sono errori in questo script? È questo il metodo giusto per quello che sto cercando di fare e in caso contrario qualcuno ha qualche suggerimento su come posso farlo? una cosa da notare è che la metà del valore potrebbe non corrispondere esattamente a un'ora, quindi cercherò l'ora prima o dopo il punto di metà misura.

 

Names Default To Here(1);

Data Table( "Data" ) << Summary(
 Group( :Sample, ),
 Max( :Measurement ),
 Freq( "None" ),
 Weight( "None" )
);

New Column( "Half Max Measure", Formula (:Name("Max(Measurement)") / 2));

New Column( "Time At Half Measurement", Format ("h:m"), Formula(
dt = Data Table( "Data" );
If(dt:Sample == Sample,
Bracket = Loc Sorted( dt:Measurement << getvalues, :Half Max Measure );
dt:Time[Bracket])));

 

 

Tabella datiScriptingRe: Problema con la tabella di ricerca/Loc ordinato

"Loc Sorted" richiede che il primo argomento sia ordinato per funzionare correttamente.

D'altra parte, quanto segue potrebbe dare quello che vuoi, supponendo che il mezzo esista tra i dati.

data table("Data") << new column("is match", 
 formula(:Measurement == Col Max( :Measurement, :Sample ) / 2)
)

Se il centro non può esistere tra i dati, controlla se un campione rientra in un intervallo che puoi definire.

Re: Problema con la tabella di ricerca/Loc ordinato

Ecco la mia opinione sulla risoluzione del problema.Gestisce i casi in cui la misurazione massima è un numero pari, e quindi esiste una riga esatta da cui ottenere l'intervallo, o se la misurazione massima è un numero dispari, interpolerà il valore del tempo per ottenere l'intervallo valore

Names Default To Here( 1 );

dt = Data Table( "Data" );

dtSum = dt << Summary(
 Group( :Sample, ),
 Max( :Measurement ),
 Freq( "None" ),
 Weight( "None" ),
 Link to Original Data Table( 0 ),
 Output Table( "The Summaries" )
);

dtSum << New Column( "Half Max Measure", Set Each Value( :Name( "Max(Measurement)" ) / 2 ) );
dtSum << New Column( "Time At Half Measurement", Format( "h:m:s" ) );

// Get the Half Max Measure
For( i = 1, i <= N Rows( dtSum ), i++,
 theRow = dt << get rows where(
  dt:Sample == dtsum:Sample[i] & dt:Measurement == dtSum:Half Max Measure[i]
 );
 If( N Rows( theRow ) > 0,
  dtSum:Time At Half Measurement[i] = dt:Time[theRow[1]]
 , 
  // No Measurement was taken at exact Half Time, so interprolate the finding
  rowBefore = Max(
   dt << get rows where(
    dt:Sample == dtsum:Sample[i] & dt:Measurement > dtSum:Half Max Measure[i]
   )
  );
  rowAfter = Min(
   dt << get rows where(
    dt:Sample == dtsum:Sample[i] & dt:Measurement < dtSum:Half Max Measure[i]
   )
  );
  ratio = (dt:Measurement[rowBefore] - dtSum:Half Max Measure[i]) / (dt:Measurement[
  rowBefore] - dt:Measurement[rowAfter]);
  dtSum:Time At Half Measurement[i] = dt:Time[rowBefore] + ratio * (dt:Time[rowAfter] -
  dt:Time[rowBefore]);
 );
);