437271_ja-JP

liliconcom

ループから行列を追加する

次のスクリプトを使用して行列を生成しようとしていますが、いくつか質問があります。

1.「行」を正しく取得するには、最初にフルーツ列をソートする必要がありますか? 「r」から数字を 1 つだけ選択するランダムな式はありますか?

2. furitName 情報 (i 変数) を含む最後の「実行」行列が必要であり、それは 1 つの行列だけです。私が持っていた現在のスクリプトは、(N Items(fruitName)に応じて) 3つの実行行列を生成します。

3. すべての実行行列が 1 つに連結されたら、その行列をデータ テーブルに出力する方法はありますか?

愛！

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
For( i = 1, i <= N Items( fruitName ), i++,
	r = dt << get rows where( :fruit == fruitName[i] );
	row = Random Integer( Max( r ) - Min( r ) );
/*show(r);
show(row);*/
	runTime = 5;
	run = [](0, 2);
	For( j = 1, j <= runTime, j++,
		row = Random Integer( Max( r ) - Min( r ) );
		run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
	);
	Show( run );
);

自動化とスクリプト作成Re: ループから行列を追加する

この機能は便利かもしれません。

 

Re: ループから行列を追加する

あなたが探していると思われることを行うためのいくつかの方法を次に示します

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
runTime = 5;
run = [](0, 2);
fruitList ={};
For( i = 1, i <= N Items( fruitName ), i++,
 r = dt << get rows where( :fruit == fruitName[i] );
 
 For( j = 1, j <= runTime, j++,
  insert into(fruitList, fruitName[i]);
  row = r[Random Integer( nrows(r))];

  run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
 );
);

dtNew = New Table("Random",
 add rows(n rows(run)),
 new column("Fruit", character,set each value(fruitList[Row()])),
 new column("Delta", set each value(run[row(),2]))
);

// or

dtNew2 = dt << Subset(
 Sample Size( runTime ),
 Selected columns only( 0 ),
 Stratify( :fruit )
);
dtNew2 << New Column( "Delta", set each value( :price hi - :price lo ) );
dtNew2 << delete columns( {"price hi", "price lo"} );