437271_it-IT

liliconcom

Aggiungi matrici da un ciclo

Sto cercando di generare una matrice con i seguenti script e ho alcune domande:

1. per ottenere correttamente la "riga" devo prima ordinare la colonna della frutta? Esiste una formula casuale per scegliere un solo numero da "r"?

2. Ho bisogno della matrice "esegui" finale con le informazioni furitName (la variabile i) e che sia solo una matrice. Lo script attuale che avevo genererebbe 3 matrici di esecuzione (a seconda degli N elementi (nomefrutta))

3. Una volta che tutte le matrici eseguite sono concatenate in una, esiste un modo per inviare la matrice a una tabella dati?

AMORE!

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
For( i = 1, i <= N Items( fruitName ), i++,
	r = dt << get rows where( :fruit == fruitName[i] );
	row = Random Integer( Max( r ) - Min( r ) );
/*show(r);
show(row);*/
	runTime = 5;
	run = [](0, 2);
	For( j = 1, j <= runTime, j++,
		row = Random Integer( Max( r ) - Min( r ) );
		run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
	);
	Show( run );
);

Automazione e scriptingRi: Aggiungi matrici da un ciclo

Questa funzione potrebbe essere utile.

 

Ri: Aggiungi matrici da un ciclo

Ecco un paio di modi per fare quello che penso tu stia cercando

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
runTime = 5;
run = [](0, 2);
fruitList ={};
For( i = 1, i <= N Items( fruitName ), i++,
 r = dt << get rows where( :fruit == fruitName[i] );
 
 For( j = 1, j <= runTime, j++,
  insert into(fruitList, fruitName[i]);
  row = r[Random Integer( nrows(r))];

  run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
 );
);

dtNew = New Table("Random",
 add rows(n rows(run)),
 new column("Fruit", character,set each value(fruitList[Row()])),
 new column("Delta", set each value(run[row(),2]))
);

// or

dtNew2 = dt << Subset(
 Sample Size( runTime ),
 Selected columns only( 0 ),
 Stratify( :fruit )
);
dtNew2 << New Column( "Delta", set each value( :price hi - :price lo ) );
dtNew2 << delete columns( {"price hi", "price lo"} );