437271_it-IT

liliconcom

Re: Aggiungere matrici da un loop

Ecco un paio di modi per fare quello che penso tu stia cercando

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
runTime = 5;
run = [](0, 2);
fruitList ={};
For( i = 1, i <= N Items( fruitName ), i++,
 r = dt << get rows where( :fruit == fruitName[i] );
 
 For( j = 1, j <= runTime, j++,
  insert into(fruitList, fruitName[i]);
  row = r[Random Integer( nrows(r))];

  run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
 );
);

dtNew = New Table("Random",
 add rows(n rows(run)),
 new column("Fruit", character,set each value(fruitList[Row()])),
 new column("Delta", set each value(run[row(),2]))
);

// or

dtNew2 = dt << Subset(
 Sample Size( runTime ),
 Selected columns only( 0 ),
 Stratify( :fruit )
);
dtNew2 << New Column( "Delta", set each value( :price hi - :price lo ) );
dtNew2 << delete columns( {"price hi", "price lo"} );

Re: Aggiungere matrici da un loop

Questa funzione potrebbe essere utile.

 

Aggiungi matrici da un ciclo

Sto cercando di generare una matrice con i seguenti script e ho alcune domande:

1. per ottenere correttamente "riga" devo prima ordinare la colonna della frutta? Esiste una formula casuale per scegliere solo un numero da "r"?

2. Ho bisogno della matrice "run" finale con le informazioni furitName (la variabile i) ed essere solo una matrice. Lo script corrente che avevo genererebbe 3 matrici di esecuzione (a seconda degli N Items (fruitName))

3. Una volta che tutte le matrici di esecuzione sono concatenate in una, c'è un modo per inviare la matrice a una tabella di dati?

 

TIA!

 

 

Names Default To Here( 1 );
dt = Current Data Table();
Summarize( dt, fruitName = by( :fruit ) );
For( i = 1, i <= N Items( fruitName ), i++,
 r = dt << get rows where( :fruit == fruitName[i] );
 row = Random Integer( Max( r ) - Min( r ) );
/*show(r);
show(row);*/
 runTime = 5;
 run = [](0, 2);
 For( j = 1, j <= runTime, j++,
  row = Random Integer( Max( r ) - Min( r ) );
  run |/= Matrix( {{j, dt:name( "price hi" )[row] - dt:price lo[row]}} );
 );
 Show( run );
);

 

Sceneggiatura