435608_ja-JP

liliconcom

JSL > GraphBuilder > マルチフレーム プロット > 動的テキスト注釈の問題

JMP コミュニティの皆様、こんにちは。

明らかに単純な問題があり、解決できませんでした。

以下のスクリプトでは、メイン データ テーブルから抽出された値に基づいて「グラフィックス スクリプトの追加」を使用してテキスト注釈を動的に追加しようとしています (添付を参照)。 問題は、複数のフレームにわたる実際のダイナミック値が、各フレームに明確に関連付けられるのではなく、データ テーブルから抽出された最後の有効なデータにすべて設定されることです。 適切な結果を得るには、「Eval Expr」と「Expr」の組み合わせを使用する必要があると思いますが、この操作の正しい構文を見つけることができませんでした。 すべての提案を歓迎します。

Names Default to Here (1);

dt = data table ("TS_DATA_TABLE_MOCK");

fdr_data = dt:FDR << Get Values ();

show (fdr_data);

 gb = dt << Graph Builder(
    Size( 832, 835 ),
    Fit to Window( "Off" ),
    Variables(
     X( :"DURATION (Week)"n ),
     Y( :LSMEAN ),
     Wrap( :M_ID ),
     Overlay( :ARM ),
     Interval( :STDERR )
    ),
    Elements( Points( X, Y, Legend( 31 ) ), Line( X, Y, Legend( 32 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "LSMEAN",
      ScaleBox,
      {Add Ref Line( 0, "Solid", "Gray", "", 2 )}
     ),
     Dispatch(
      {},
      "400",
      ScaleBox,
      {Legend Model(
       31,
       Base( 0, 0, 0, Item ID( "A", 1 ) ),
       Base( 1, 0, 0, Item ID( "B", 1 ) )
      )}
     )
    )
   );

gbr = report (gb);

nfr = N items (gbr << Xpath ("//FrameBox"));

For (i = 0, i <= nfr-2, i++,
 
 a_fdr4 = "fdr " || CHAR(Format(fdr_data [ (i*6) + 4], "PValue"));
 a_fdr14 = "fdr " || CHAR(Format(fdr_data [ (i*6) + 6], "PValue"));
 b_fdr4 = "fdr " || CHAR(Format(fdr_data [ (i*6) + 3], "PValue"));
 b_fdr14 = "fdr " || CHAR(Format(fdr_data [ (i*6) + 5], "PValue"));
 
 
 
 locfr = gbr [FrameBox (i+1)];
 locfr << add graphics script (
   Text size (8);
   Text color (blue);
   Text (Center Justified, {4, -0.15}, a_fdr4);
   Text (Center Justified, {14, -0.15}, a_fdr14);
   Text color (green);
   Text (Center Justified, {4, -0.2}, b_fdr4);
   Text (Center Justified, {14, -0.2}, b_fdr14);
 );
 
);

これは、この形式でプロットする特定の行を選択する大きなスクリプトの一部です。

一番、

TS

グラフィックスクリプティングRe: JSL > GraphBuilder > マルチフレーム プロット > 動的テキスト注釈の問題

こんにちは。

いつものように素晴らしい。 私はまだ Eval / Eval Expr / Expr の構成に苦労しています。

一番、

TS

Re: JSL > GraphBuilder > マルチフレーム プロット > 動的テキスト注釈の問題

Eval(EvalExpr()) の場合は、これを試してください：

 Eval(EvalExpr(locfr << add graphics script(
  Text Size(8);
  Text Color(blue);
  Text(Center Justified, {4, -0.15}, Expr(a_fdr4));
  Text(Center Justified, {14, -0.15}, Expr(a_fdr14));
  Text Color(green);
  Text(Center Justified, {4, -0.2}, Expr(b_fdr4));
  Text(Center Justified, {14, -0.2}, Expr(b_fdr14));
 )));

少なくともカスタマイズ グラフの値は更新されているようで、値は各グループで同じではありません。